BUILD.gn

# Copyright 2016 The Chromium Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

if (is_android) {
  import("//build/config/android/config.gni")
  import("//build/config/android/rules.gni")
}

declare_args() {
  # Enables the blimp client. This is required to get the actual implementation
  # of blimp.
  # By default, only a dummy-implementation is provided.
  enable_blimp_client = false
}

# This target is here to let //chrome depend on //blimp/client/public
# and automatically get the correct implementation of //blimp/client/core
# depending on whether enable_blimp_client is set or not.
group("core_shim") {
  visibility = [ "//blimp/client/public" ]

  if (enable_blimp_client) {
    deps = [
      ":core",
    ]
  } else {
    deps = [
      ":dummy_core",
    ]
  }
}

group("core") {
  visibility = [ "//blimp/client/*" ]

  deps = [
    ":context",
    ":switches",
    "//blimp/client/core/compositor",
    "//blimp/client/core/contents",
    "//blimp/client/core/session",
  ]
}

source_set("dummy_core") {
  visibility = [ ":*" ]

  sources = [
    "dummy_blimp_client_context.cc",
    "dummy_blimp_client_context.h",
  ]

  deps = [
    "//base",
    "//blimp/client/public:public_headers",
    "//url",
  ]

  if (is_android) {
    sources += [
      "android/dummy_blimp_client_context_android.cc",
      "android/dummy_blimp_client_context_android.h",
      "android/dummy_blimp_jni_registrar.cc",
    ]

    deps += [ ":dummy_core_jni_headers" ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "blimp_client_context_impl_unittest.cc",
  ]

  deps = [
    ":context",
    "//blimp/client/core/compositor:unit_tests",
    "//blimp/client/core/contents:unit_tests",
    "//blimp/client/core/session:unit_tests",
    "//blimp/client/public:public_headers",
    "//blimp/client/test",
    "//testing/gtest",
  ]
}

source_set("context") {
  sources = [
    "blimp_client_context_impl.cc",
    "blimp_client_context_impl.h",
  ]

  public_deps = [
    "//base",
    "//blimp/client/core/contents",
    "//blimp/client/public:public_headers",
  ]

  if (is_android) {
    sources += [
      "android/blimp_client_context_impl_android.cc",
      "android/blimp_client_context_impl_android.h",
      "android/blimp_jni_registrar.cc",
    ]

    deps = [
      ":context_jni_headers",
    ]
  }
}

source_set("switches") {
  visibility = [
    "//blimp/client/*",
    "//blimp/engine:browser_tests",
  ]

  sources = [
    "blimp_client_switches.cc",
    "blimp_client_switches.h",
  ]
}

if (is_android) {
  # This target is here to let //chrome depend on
  # //blimp/client/public:public_java and automatically get the correct
  # implementation of //blimp/client/core depending on whether
  # enable_blimp_client is set or not.
  java_group("core_shim_java") {
    visibility = [ "//blimp/client/public/*" ]

    if (enable_blimp_client) {
      deps = [
        ":core_java",
      ]
    } else {
      deps = [
        ":dummy_core_java",
      ]
    }
  }

  java_group("core_java") {
    visibility = [ "//blimp/client/*" ]

    deps = [
      ":context_java",
      ":settings_java",
      ":switches_java",
      "//blimp/client/core/contents:contents_java",
    ]
  }

  android_library("dummy_core_java") {
    visibility = [ ":*" ]

    java_files = [ "android/java/src/org/chromium/blimp/core/DummyBlimpClientContext.java" ]

    deps = [
      "//base:base_java",
      "//blimp/client/public:public_headers_java",
    ]
  }

  android_library("context_java") {
    visibility = [ "//blimp/client/*" ]

    java_files = [ "android/java/src/org/chromium/blimp/core/BlimpClientContextImpl.java" ]

    deps = [
      "//base:base_java",
      "//blimp/client/core:settings_java",
      "//blimp/client/core/contents:contents_java",
      "//blimp/client/public:public_headers_java",
    ]
  }

  android_library("switches_java") {
    visibility = [ "//blimp/client/*" ]

    java_files =
        [ "android/java/src/org/chromium/blimp/core/BlimpClientSwitches.java" ]
  }

  android_library("settings_java") {
    visibility = [ "//blimp/client/*" ]

    java_files = [ "android/java/src/org/chromium/blimp/core/settings/AboutBlimpPreferences.java" ]

    # TODO(xingliu): Remove android support v7 dependency and move android resources to Chrome
    # after Blimp merge to Chrome.
    deps = [
      "//base:base_java",
      "//blimp/client:blimp_java_resources",
      "//blimp/client/public:public_headers_java",
      "//third_party/android_tools:android_support_v7_appcompat_java",
    ]
  }

  generate_jni("context_jni_headers") {
    visibility = [ ":*" ]

    sources = [
      "android/java/src/org/chromium/blimp/core/BlimpClientContextImpl.java",
    ]

    jni_package = "blimp/client/core"
  }

  generate_jni("dummy_core_jni_headers") {
    visibility = [ ":*" ]

    sources = [
      "android/java/src/org/chromium/blimp/core/DummyBlimpClientContext.java",
    ]

    jni_package = "blimp/client/core"
  }
}