-
Notifications
You must be signed in to change notification settings - Fork 1
/
ldap.rkt
157 lines (129 loc) · 4.93 KB
/
ldap.rkt
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
#lang racket/base
(require racket/class
racket/contract
"ffi.rkt")
(provide
(contract-out
[ldap%
(class/c
(init [host string?]
[version (or/c 2 3)])
(init-field [root-dn (or/c string? #f)]
[password (or/c string? #f)])
[set-option (->m positive? positive? #t)]
[bind (->*m () ((or/c 0 1 2)) #t)]
[modify (->m string? mod-list? #t)]
[add (->m string? mod-list? #t)]
[delete (->m string? #t)]
[search (->m string? string? (or/c 0 1 2) #t)]
[search* (->m string? string? (or/c 0 1 2) (listof list?))]
[compare (->m string? string? string? boolean?)]
[get-data (->m (listof list?))]
[count-entries (->m (or/c zero? positive?))]
[set-password (->m string? string? string? boolean?)]
[rename-dn (->m string? string? string? (or/c 0 1) #t)]
[unbind (->m #t)]
[clear (->m void?)])])
(struct-out exn:fail:ldap))
(define mod-list? (listof (list/c number? string? (listof string?))))
(define-struct (exn:fail:ldap exn:fail:user) ())
(define (raise-ldap-error msg)
(raise (exn:fail:ldap msg (current-continuation-marks))))
(define ldap%
(class object%
(super-new)
(init host
[version 3])
(init-field [root-dn #f]
[password #f])
(define-values (initialized ld)
(ldap-initialize host))
(define ldap-data (box '(())))
(define ldap-valid (box #f))
(define ldap-message-c-ptr (box #f))
(define (return-true-or-raise-error r)
(or (zero? r)
(raise-ldap-error (ldap-err2string r))))
(define (do-thunk-or-raise-error r thunk)
(if (zero? r)
(thunk)
(raise-ldap-error (ldap-err2string r))))
;; check ldap initialize code
(return-true-or-raise-error initialized)
;; set protocol version
(set-option #x0011 version)
(define/private (read-ldap-message
[ldap-message (unbox ldap-message-c-ptr)])
(define temp null)
(let loop ([e ldap-message])
(when e
(define-values (fst-attr ber) (ldap-first-attribute ld e))
(define g (list (cons "dn" (ldap-get-dn ld e))))
(let inner-loop ([attr fst-attr])
(when attr
(define vals (ldap-get-values-len ld e attr))
(for ([i (ldap-count-values-len vals)])
(set! g (cons (cons attr (get-ber-value vals i)) g)))
(ldap-value-free-len vals)
(inner-loop (ldap-next-attribute ld e ber))))
(set! temp (cons (reverse g) temp))
(loop (ldap-next-entry ld e))))
(set-box! ldap-data (reverse temp))
#t)
(define/public (set-option key value)
(return-true-or-raise-error (ldap-set-option ld key value)))
(define/public (bind [mechanism 0])
(if (unbox ldap-valid)
(raise-ldap-error "ldap is already bound")
(do-thunk-or-raise-error
(ldap-sasl-bind-s ld root-dn mechanism password #f #f #f)
(λ () (set-box! ldap-valid #t) #t))))
(define/private (add-modify ldap-ffi-fn user-dn mod-list)
(return-true-or-raise-error (ldap-ffi-fn ld user-dn mod-list #f #f)))
(define/public (modify user-dn mod-list)
(add-modify ldap-modify-ext-s user-dn mod-list))
(define/public (add user-dn mod-list)
(add-modify ldap-add-ext-s user-dn mod-list))
(define/public (delete dn)
(return-true-or-raise-error (ldap-delete-ext-s ld #f #f)))
(define/public (search base-dn fltr scope)
(define-values (r msg)
(ldap-search-ext-s ld base-dn scope fltr #f 0 #f #f #f 0))
(do-thunk-or-raise-error
r (λ ()
(set-box! ldap-message-c-ptr msg)
(read-ldap-message msg) #t)))
(define/public (search* base-dn fltr scope)
(search base-dn fltr scope)
(begin0
(unbox ldap-data)
(set-box! ldap-data '(()))))
(define/public (get-data)
(unbox ldap-data))
(define/public (compare dn attr value)
;; LDAP_COMPARE_FALSE 0x05
;; LDAP_COMPARE_TRUE 0x06
(define r (ldap-compare-ext-s ld dn attr value #f #f))
(case r
[(#x05) #f]
[(#x06) #t]
[else (raise-ldap-error (ldap-err2string r))]))
(define/public (count-entries)
(ldap-count-entries ld (unbox ldap-message-c-ptr)))
(define/public (set-password user oldpw newpw)
(define r (ldap-passwd-s ld user oldpw newpw #f #f))
(case r
[(1) #f]
[(0) #t]
[else (raise-ldap-error (ldap-err2string r))]))
(define/public (rename-dn dn newrdn new-superior delete-old-rdn)
(return-true-or-raise-error
(ldap-rename-s ld dn newrdn new-superior delete-old-rdn #f #f)))
(define/public (unbind)
(if (unbox ldap-valid)
(do-thunk-or-raise-error
(ldap-unbind-ext-s ld #f #f)
(λ () (set-box! ldap-valid #f) #t))
(raise-ldap-error "ldap is already unbound")))
(define/public (clear)
(set-box! ldap-data '(())))))