forked from graemecan/raymond_aqual
-
Notifications
You must be signed in to change notification settings - Fork 0
/
rho_fine.f90
2162 lines (2002 loc) · 66.5 KB
/
rho_fine.f90
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
!##############################################################################
!##############################################################################
!##############################################################################
!##############################################################################
subroutine rho_fine(ilevel,icount)
use amr_commons
use pm_commons
use hydro_commons
use poisson_commons
use cooling_module
use mpi_mod
use dice_commons
implicit none
#ifndef WITHOUTMPI
integer::info
real(kind=8),dimension(1:ndim+1)::multipole_in,multipole_out
#endif
integer::ilevel,icount
!------------------------------------------------------------------
! This routine computes the density field at level ilevel using
! the CIC scheme. Particles that are not entirely in
! level ilevel contribute also to the level density field
! (boundary particles) using buffer grids.
! Array flag1, flag2 and phi are used as temporary work space.
! Array rho and cpu_map2 are stored with:
! - rho containing the Poisson source term
! - cpu_map2 containing the refinement map due to particle
! number density criterion (quasi Lagrangian mesh).
!------------------------------------------------------------------
integer::iskip,icpu,ind,i,nx_loc,ibound,ncell
real(dp)::dx,d_scale,scale,dx_loc,scalar
if(.not. poisson)return
if(numbtot(1,ilevel)==0)return
if(verbose)write(*,111)ilevel
! Mesh spacing in that level
dx=0.5D0**ilevel
nx_loc=icoarse_max-icoarse_min+1
scale=boxlen/dble(nx_loc)
dx_loc=dx*scale
if(ilevel==levelmin)multipole=0d0
! Temporary use of an array used in hydro solver
! to have an analytic density without hydrodynamics
! This is allocated here because with hydro == false
! init_hydro is never called.
if (.not. hydro .and. gravity_type < 0) then
print *,"Analytic rho being used without hydro."
ncell=ncoarse+twotondim*ngridmax
allocate(unew(1:ncell,1:ndim+1))
endif
!-------------------------------------------------------
! Initialize rho to analytical and baryon density field
!-------------------------------------------------------
if(dice_init.and.amr_struct) then
if(hydro)call multipole_from_current_level(ilevel)
call cic_from_multipole(ilevel)
! Update boundaries
call make_virtual_reverse_dp(rho(1),ilevel)
call make_virtual_fine_dp (rho(1),ilevel)
else
if(ilevel==levelmin.or.icount>1)then
do i=nlevelmax,ilevel,-1
! Compute mass multipole
if(hydro)call multipole_fine(i)
! GC: call to multipole_fine if analytic density is required, even without hydro
if(.not. hydro .and. gravity_type < 0)call multipole_fine(i)
! Perform TSC using pseudo-particle
#ifdef TSC
if (ndim==3)then
call tsc_from_multipole(i)
else
write(*,*)'TSC not supported for ndim neq 3'
call clean_stop
end if
#else
! Perform CIC using pseudo-particle
call cic_from_multipole(i)
#endif
! Update boundaries
call make_virtual_reverse_dp(rho(1),i)
call make_virtual_fine_dp (rho(1),i)
end do
end if
! deallocate temporarily used hydro array in case of analytic density
! without hydro
if (.not. hydro .and. gravity_type < 0) then
deallocate(unew)
endif
!--------------------------
! Initialize fields to zero
!--------------------------
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,active(ilevel)%ngrid
phi(active(ilevel)%igrid(i)+iskip)=0.0D0
end do
if(ilevel==cic_levelmax)then
do i=1,active(ilevel)%ngrid
rho_top(active(ilevel)%igrid(i)+iskip)=0.0D0
end do
endif
end do
if(cic_levelmax>0.and.ilevel>cic_levelmax)then
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,active(ilevel)%ngrid
rho_top(active(ilevel)%igrid(i)+iskip)=rho_top(father(active(ilevel)%igrid(i)))
rho(active(ilevel)%igrid(i)+iskip)=rho(active(ilevel)%igrid(i)+iskip)+ &
& rho_top(active(ilevel)%igrid(i)+iskip)
end do
end do
endif
!-------------------------------------------------------------------------
! Initialize "number density" field to baryon number density in array phi.
!-------------------------------------------------------------------------
if(m_refine(ilevel)>-1.0d0)then
d_scale=max(mass_sph/dx_loc**ndim,smallr)
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
if(hydro)then
if(ivar_refine>0)then
do i=1,active(ilevel)%ngrid
scalar=uold(active(ilevel)%igrid(i)+iskip,ivar_refine) &
& /max(uold(active(ilevel)%igrid(i)+iskip,1),smallr)
if(scalar>var_cut_refine)then
phi(active(ilevel)%igrid(i)+iskip)= &
& rho(active(ilevel)%igrid(i)+iskip)/d_scale
endif
end do
else
do i=1,active(ilevel)%ngrid
phi(active(ilevel)%igrid(i)+iskip)= &
& rho(active(ilevel)%igrid(i)+iskip)/d_scale
end do
endif
endif
end do
endif
!-------------------------------------------------------
! Initialize rho and phi to zero in virtual boundaries
!-------------------------------------------------------
do icpu=1,ncpu
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,reception(icpu,ilevel)%ngrid
rho(reception(icpu,ilevel)%igrid(i)+iskip)=0.0D0
phi(reception(icpu,ilevel)%igrid(i)+iskip)=0.0D0
end do
if(ilevel==cic_levelmax)then
do i=1,reception(icpu,ilevel)%ngrid
rho_top(reception(icpu,ilevel)%igrid(i)+iskip)=0.0D0
end do
endif
end do
end do
!---------------------------------------------------------
! Compute particle contribution to density field
!---------------------------------------------------------
! Compute density due to current level particles
if(pic)then
call rho_from_current_level(ilevel)
end if
! Update boudaries
call make_virtual_reverse_dp(rho(1),ilevel)
call make_virtual_fine_dp (rho(1),ilevel)
if(ilevel==cic_levelmax)then
call make_virtual_reverse_dp(rho_top(1),ilevel)
endif
if(cic_levelmax>0.and.ilevel>=cic_levelmax)then
call make_virtual_fine_dp (rho_top(1),ilevel)
endif
if(m_refine(ilevel)>-1.0d0)then
call make_virtual_reverse_dp(phi(1),ilevel)
call make_virtual_fine_dp (phi(1),ilevel)
endif
!--------------------------------------------------------------
! Compute multipole contribution from all cpus and set rho_tot
!--------------------------------------------------------------
#ifndef WITHOUTMPI
if(ilevel==levelmin)then
multipole_in=multipole
call MPI_ALLREDUCE(multipole_in,multipole_out,ndim+1,MPI_DOUBLE_PRECISION,MPI_SUM,MPI_COMM_WORLD,info)
multipole=multipole_out
endif
#endif
if(nboundary==0)then
rho_tot=multipole(1)/scale**ndim
if(debug)write(*,*)'rho_average=',rho_tot
else
rho_tot=0d0
endif
!----------------------------------------------------
! Reset rho and phi in physical boundaries
!----------------------------------------------------
do ibound=1,nboundary
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,boundary(ibound,ilevel)%ngrid
phi(boundary(ibound,ilevel)%igrid(i)+iskip)=0.0
rho(boundary(ibound,ilevel)%igrid(i)+iskip)=0.0
end do
end do
end do
!-----------------------------------------
! Compute quasi Lagrangian refinement map
!-----------------------------------------
if(m_refine(ilevel)>-1.0d0)then
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,active(ilevel)%ngrid
if(phi(active(ilevel)%igrid(i)+iskip)>=m_refine(ilevel))then
cpu_map2(active(ilevel)%igrid(i)+iskip)=1
else
cpu_map2(active(ilevel)%igrid(i)+iskip)=0
end if
end do
end do
! Update boundaries
call make_virtual_fine_int(cpu_map2(1),ilevel)
end if
!!$ do ind=1,twotondim
!!$ iskip=ncoarse+(ind-1)*ngridmax
!!$ do i=1,active(ilevel)%ngrid
!!$ print*,rho(active(ilevel)%igrid(i)+iskip),rho_tot
!!$ end do
!!$ end do
111 format(' Entering rho_fine for level ',I2)
end subroutine rho_fine
!##############################################################################
!##############################################################################
!##############################################################################
!##############################################################################
subroutine rho_from_current_level(ilevel)
use amr_commons
use pm_commons
use hydro_commons
use poisson_commons
implicit none
integer::ilevel
!------------------------------------------------------------------
! This routine computes the density field at level ilevel using
! the CIC scheme from particles that are not entirely in
! level ilevel (boundary particles).
! Arrays flag1 and flag2 are used as temporary work space.
!------------------------------------------------------------------
integer::igrid,jgrid,ipart,jpart,idim,icpu
integer::i,ig,ip,npart1
real(dp)::dx
integer,dimension(1:nvector),save::ind_grid,ind_cell
integer,dimension(1:nvector),save::ind_part,ind_grid_part
real(dp),dimension(1:nvector,1:ndim),save::x0
! Mesh spacing in that level
dx=0.5D0**ilevel
! Loop over cpus
do icpu=1,ncpu
! Loop over grids
igrid=headl(icpu,ilevel)
ig=0
ip=0
do jgrid=1,numbl(icpu,ilevel)
npart1=numbp(igrid) ! Number of particles in the grid
if(npart1>0)then
ig=ig+1
ind_grid(ig)=igrid
ipart=headp(igrid)
! Loop over particles
do jpart=1,npart1
if(ig==0)then
ig=1
ind_grid(ig)=igrid
end if
ip=ip+1
ind_part(ip)=ipart
ind_grid_part(ip)=ig
if(ip==nvector)then
! Lower left corner of 3x3x3 grid-cube
do idim=1,ndim
do i=1,ig
x0(i,idim)=xg(ind_grid(i),idim)-3.0D0*dx
end do
end do
do i=1,ig
ind_cell(i)=father(ind_grid(i))
end do
#ifdef TSC
call tsc_amr(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
#else
call cic_amr(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
#endif
ip=0
ig=0
end if
ipart=nextp(ipart) ! Go to next particle
end do
! End loop over particles
end if
igrid=next(igrid) ! Go to next grid
end do
! End loop over grids
if(ip>0)then
! Lower left corner of 3x3x3 grid-cube
do idim=1,ndim
do i=1,ig
x0(i,idim)=xg(ind_grid(i),idim)-3.0D0*dx
end do
end do
do i=1,ig
ind_cell(i)=father(ind_grid(i))
end do
#ifdef TSC
call tsc_amr(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
#else
call cic_amr(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
#endif
end if
end do
! End loop over cpus
end subroutine rho_from_current_level
subroutine multipole_from_current_level(ilevel)
use amr_commons
use pm_commons
use hydro_commons
use poisson_commons
implicit none
integer::ilevel
!------------------------------------------------------------------
! This routine computes the density field at level ilevel using
! the CIC scheme from particles that are not entirely in
! level ilevel (boundary particles).
! Arrays flag1 and flag2 are used as temporary work space.
!------------------------------------------------------------------
integer::igrid,jgrid,ipart,jpart,idim,icpu,ind,iskip,ibound
integer::j,ig,ip,npart1,npart2,next_part
real(dp)::dx
integer,dimension(1:nvector),save::ind_grid,ind_cell
integer,dimension(1:nvector),save::ind_part,ind_grid_part
real(dp),dimension(1:nvector,1:ndim),save::x0
!!!!!!!!!!!!!!!!!!!!!!!!!!!
integer ::nx_loc
real(dp),dimension(1:twotondim,1:3)::xc
integer ::ix,iy,iz
real(kind=8)::dx_loc,scale,vol_loc
real(dp),dimension(1:3)::skip_loc
! Mesh spacing in that level
dx=0.5D0**ilevel
nx_loc=(icoarse_max-icoarse_min+1)
skip_loc=(/0.0d0,0.0d0,0.0d0/)
if(ndim>0)skip_loc(1)=dble(icoarse_min)
if(ndim>1)skip_loc(2)=dble(jcoarse_min)
if(ndim>2)skip_loc(3)=dble(kcoarse_min)
scale=boxlen/dble(nx_loc)
dx_loc=dx*scale
vol_loc=dx_loc**ndim
do ind=1,twotondim
iz=(ind-1)/4
iy=(ind-1-4*iz)/2
ix=(ind-1-2*iy-4*iz)
if(ndim>0)xc(ind,1)=(dble(ix)-0.5D0)*dx
if(ndim>1)xc(ind,2)=(dble(iy)-0.5D0)*dx
if(ndim>2)xc(ind,3)=(dble(iz)-0.5D0)*dx
end do
!!!!!!!!!!!!!!!!!!!!!!!!!!!
if(verbose)write(*,111)ilevel
! Mesh spacing in that level
dx=0.5D0**ilevel
! Initialize unew field to zero
do icpu=1,ncpu
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do idim=1,ndim+1
do j=1,reception(icpu,ilevel)%ngrid
unew(reception(icpu,ilevel)%igrid(j)+iskip,idim)=0.0D0
end do
end do
end do
end do
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do idim=1,ndim+1
do j=1,active(ilevel)%ngrid
unew(active(ilevel)%igrid(j)+iskip,idim)=0.0D0
end do
end do
end do
! Reset unew in physical boundaries
do ibound=1,nboundary
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do idim=1,ndim+1
do j=1,boundary(ibound,ilevel)%ngrid
unew(boundary(ibound,ilevel)%igrid(j)+iskip,idim)=0.0
end do
end do
end do
end do
! Loop over cpus
do icpu=1,ncpu
! Loop over grids
igrid=headl(icpu,ilevel)
ig=0
ip=0
do jgrid=1,numbl(icpu,ilevel)
npart1=numbp(igrid) ! Number of particles in the grid
npart2=0
! Count gas particles
if(npart1>0)then
ipart=headp(igrid)
! Loop over particles
do jpart=1,npart1
! Save next particle <--- Very important !!!
next_part=nextp(ipart)
if(idp(ipart).eq.1)then
npart2=npart2+1
endif
ipart=next_part ! Go to next particle
end do
endif
if(npart2>0)then
ig=ig+1
ind_grid(ig)=igrid
ipart=headp(igrid)
! Loop over particles
do jpart=1,npart1
! Save next particle <--- Very important !!!
next_part=nextp(ipart)
! Select only gas particles
if(idp(ipart).eq.1)then
if(ig==0)then
ig=1
ind_grid(ig)=igrid
end if
ip=ip+1
ind_part(ip)=ipart
ind_grid_part(ip)=ig
endif
if(ip==nvector)then
! Lower left corner of 3x3x3 grid-cube
do idim=1,ndim
do j=1,ig
x0(j,idim)=xg(ind_grid(j),idim)-3.0D0*dx
end do
end do
do j=1,ig
ind_cell(j)=father(ind_grid(j))
end do
call ngp_amr_gas(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
ip=0
ig=0
end if
ipart=next_part ! Go to next particle
end do
! End loop over particles
end if
igrid=next(igrid) ! Go to next grid
end do
! End loop over grids
if(ip>0)then
! Lower left corner of 3x3x3 grid-cube
do idim=1,ndim
do j=1,ig
x0(j,idim)=xg(ind_grid(j),idim)-3.0D0*dx
end do
end do
do j=1,ig
ind_cell(j)=father(ind_grid(j))
end do
call ngp_amr_gas(ind_cell,ind_part,ind_grid_part,x0,ig,ip,ilevel)
end if
end do
! End loop over cpus
! Update boundaries
do idim=1,ndim+1
call make_virtual_reverse_dp(unew(1,idim),ilevel)
call make_virtual_fine_dp(unew(1,idim),ilevel)
end do
! Check for over-refinement
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do j=1,active(ilevel)%ngrid
if(unew(active(ilevel)%igrid(j)+iskip,1)==0d0) then
unew(active(ilevel)%igrid(j)+iskip,1)=smallr*vol_loc
do idim=1,ndim
unew(active(ilevel)%igrid(j)+iskip,idim+1)=(xg(active(ilevel)%igrid(j),idim)+xc(ind,idim)-skip_loc(idim))*scale &
& *unew(active(ilevel)%igrid(j)+iskip,1)
end do
endif
end do
end do
do idim=1,ndim+1
call make_virtual_fine_dp(unew(1,idim),ilevel)
end do
111 format(' Entering multipole_from_current_level for level',i2)
end subroutine multipole_from_current_level
!##############################################################################
!##############################################################################
!##############################################################################
!##############################################################################
subroutine cic_amr(ind_cell,ind_part,ind_grid_part,x0,ng,np,ilevel)
use amr_commons
use pm_commons
use poisson_commons
use dice_commons
use hydro_commons, ONLY: mass_sph
implicit none
integer::ng,np,ilevel
integer ,dimension(1:nvector)::ind_cell,ind_grid_part,ind_part
real(dp),dimension(1:nvector,1:ndim)::x0
!------------------------------------------------------------------
! This routine computes the density field at level ilevel using
! the CIC scheme. Only cells that are in level ilevel
! are updated by the input particle list.
!------------------------------------------------------------------
logical::error
integer::j,ind,idim,nx_loc
real(dp)::dx,dx_loc,scale,vol_loc
! Grid-based arrays
integer ,dimension(1:nvector,1:threetondim),save::nbors_father_cells
integer ,dimension(1:nvector,1:twotondim),save::nbors_father_grids
! Particle-based arrays
logical ,dimension(1:nvector),save::ok
real(dp),dimension(1:nvector),save::mmm
real(dp),dimension(1:nvector),save::ttt=0d0
! Save type
type(part_t),dimension(1:nvector),save::fam
real(dp),dimension(1:nvector),save::vol2
real(dp),dimension(1:nvector,1:ndim),save::x,dd,dg
integer ,dimension(1:nvector,1:ndim),save::ig,id,igg,igd,icg,icd
real(dp),dimension(1:nvector,1:twotondim),save::vol
integer ,dimension(1:nvector,1:twotondim),save::igrid,icell,indp,kg
real(dp),dimension(1:3)::skip_loc
! Mesh spacing in that level
dx=0.5D0**ilevel
nx_loc=(icoarse_max-icoarse_min+1)
skip_loc=(/0.0d0,0.0d0,0.0d0/)
if(ndim>0)skip_loc(1)=dble(icoarse_min)
if(ndim>1)skip_loc(2)=dble(jcoarse_min)
if(ndim>2)skip_loc(3)=dble(kcoarse_min)
scale=boxlen/dble(nx_loc)
dx_loc=dx*scale
vol_loc=dx_loc**ndim
! Gather neighboring father cells (should be present anytime !)
call get3cubefather(ind_cell,nbors_father_cells,nbors_father_grids,ng,ilevel)
! Rescale particle position at level ilevel
do idim=1,ndim
do j=1,np
x(j,idim)=xp(ind_part(j),idim)/scale+skip_loc(idim)
end do
end do
do idim=1,ndim
do j=1,np
x(j,idim)=x(j,idim)-x0(ind_grid_part(j),idim)
end do
end do
do idim=1,ndim
do j=1,np
x(j,idim)=x(j,idim)/dx
end do
end do
! Gather particle mass and family
do j=1,np
fam(j) = typep(ind_part(j))
if (is_tracer(fam(j))) then
mmm(j)=0.0d0
else
mmm(j)=mp(ind_part(j))
end if
end do
! FIXME: should use mmm instead of mp, but gives different binary output
! for no reason that I can think of
if(ilevel==levelmin)then
do j=1,np
multipole(1)=multipole(1)+mp(ind_part(j))
! multipole(1)=multipole(1)+mmm(j)
end do
do idim=1,ndim
do j=1,np
multipole(idim+1)=multipole(idim+1)+mp(ind_part(j))*xp(ind_part(j),idim)
! multipole(idim+1)=multipole(idim+1)+mmm(j)*xp(ind_part(j),idim)
end do
end do
end if
! Gather particle birth epoch
if(star)then
do j=1,np
ttt(j)=tp(ind_part(j))
end do
endif
! Check for illegal moves
error=.false.
do idim=1,ndim
do j=1,np
if(x(j,idim)<0.5D0.or.x(j,idim)>5.5D0)error=.true.
end do
end do
if(error)then
write(*,*)'problem in cic'
do idim=1,ndim
do j=1,np
if(x(j,idim)<0.5D0.or.x(j,idim)>5.5D0)then
write(*,*)x(j,1:ndim)
endif
end do
end do
stop
end if
! CIC at level ilevel (dd: right cloud boundary; dg: left cloud boundary)
do idim=1,ndim
do j=1,np
dd(j,idim)=x(j,idim)+0.5D0
id(j,idim)=int(dd(j,idim))
dd(j,idim)=dd(j,idim)-id(j,idim)
dg(j,idim)=1.0D0-dd(j,idim)
ig(j,idim)=id(j,idim)-1
end do
end do
! Compute cloud volumes
#if NDIM==1
do j=1,np
vol(j,1)=dg(j,1)
vol(j,2)=dd(j,1)
end do
#endif
#if NDIM==2
do j=1,np
vol(j,1)=dg(j,1)*dg(j,2)
vol(j,2)=dd(j,1)*dg(j,2)
vol(j,3)=dg(j,1)*dd(j,2)
vol(j,4)=dd(j,1)*dd(j,2)
end do
#endif
#if NDIM==3
do j=1,np
vol(j,1)=dg(j,1)*dg(j,2)*dg(j,3)
vol(j,2)=dd(j,1)*dg(j,2)*dg(j,3)
vol(j,3)=dg(j,1)*dd(j,2)*dg(j,3)
vol(j,4)=dd(j,1)*dd(j,2)*dg(j,3)
vol(j,5)=dg(j,1)*dg(j,2)*dd(j,3)
vol(j,6)=dd(j,1)*dg(j,2)*dd(j,3)
vol(j,7)=dg(j,1)*dd(j,2)*dd(j,3)
vol(j,8)=dd(j,1)*dd(j,2)*dd(j,3)
end do
#endif
! Compute parent grids
do idim=1,ndim
do j=1,np
igg(j,idim)=ig(j,idim)/2
igd(j,idim)=id(j,idim)/2
end do
end do
#if NDIM==1
do j=1,np
kg(j,1)=1+igg(j,1)
kg(j,2)=1+igd(j,1)
end do
#endif
#if NDIM==2
do j=1,np
kg(j,1)=1+igg(j,1)+3*igg(j,2)
kg(j,2)=1+igd(j,1)+3*igg(j,2)
kg(j,3)=1+igg(j,1)+3*igd(j,2)
kg(j,4)=1+igd(j,1)+3*igd(j,2)
end do
#endif
#if NDIM==3
do j=1,np
kg(j,1)=1+igg(j,1)+3*igg(j,2)+9*igg(j,3)
kg(j,2)=1+igd(j,1)+3*igg(j,2)+9*igg(j,3)
kg(j,3)=1+igg(j,1)+3*igd(j,2)+9*igg(j,3)
kg(j,4)=1+igd(j,1)+3*igd(j,2)+9*igg(j,3)
kg(j,5)=1+igg(j,1)+3*igg(j,2)+9*igd(j,3)
kg(j,6)=1+igd(j,1)+3*igg(j,2)+9*igd(j,3)
kg(j,7)=1+igg(j,1)+3*igd(j,2)+9*igd(j,3)
kg(j,8)=1+igd(j,1)+3*igd(j,2)+9*igd(j,3)
end do
#endif
do ind=1,twotondim
do j=1,np
igrid(j,ind)=son(nbors_father_cells(ind_grid_part(j),kg(j,ind)))
end do
end do
! Compute parent cell position
do idim=1,ndim
do j=1,np
icg(j,idim)=ig(j,idim)-2*igg(j,idim)
icd(j,idim)=id(j,idim)-2*igd(j,idim)
end do
end do
#if NDIM==1
do j=1,np
icell(j,1)=1+icg(j,1)
icell(j,2)=1+icd(j,1)
end do
#endif
#if NDIM==2
do j=1,np
icell(j,1)=1+icg(j,1)+2*icg(j,2)
icell(j,2)=1+icd(j,1)+2*icg(j,2)
icell(j,3)=1+icg(j,1)+2*icd(j,2)
icell(j,4)=1+icd(j,1)+2*icd(j,2)
end do
#endif
#if NDIM==3
do j=1,np
icell(j,1)=1+icg(j,1)+2*icg(j,2)+4*icg(j,3)
icell(j,2)=1+icd(j,1)+2*icg(j,2)+4*icg(j,3)
icell(j,3)=1+icg(j,1)+2*icd(j,2)+4*icg(j,3)
icell(j,4)=1+icd(j,1)+2*icd(j,2)+4*icg(j,3)
icell(j,5)=1+icg(j,1)+2*icg(j,2)+4*icd(j,3)
icell(j,6)=1+icd(j,1)+2*icg(j,2)+4*icd(j,3)
icell(j,7)=1+icg(j,1)+2*icd(j,2)+4*icd(j,3)
icell(j,8)=1+icd(j,1)+2*icd(j,2)+4*icd(j,3)
end do
#endif
! Compute parent cell adress
do ind=1,twotondim
do j=1,np
indp(j,ind)=ncoarse+(icell(j,ind)-1)*ngridmax+igrid(j,ind)
end do
end do
! Update mass density and number density fields
do ind=1,twotondim
do j=1,np
ok(j)=(igrid(j,ind)>0).and.is_not_tracer(fam(j))
if(dice_init) ok(j)=ok(j).and.(idp(ind_part(j)).ne.1)
end do
do j=1,np
vol2(j)=mmm(j)*vol(j,ind)/vol_loc
end do
if(cic_levelmax==0.or.ilevel<=cic_levelmax)then
do j=1,np
if(ok(j))then
rho(indp(j,ind))=rho(indp(j,ind))+vol2(j)
end if
end do
else if(ilevel>cic_levelmax)then
do j=1,np
! check for non-DM (and non-tracer)
if ( ok(j) .and. is_not_DM(fam(j)) ) then
rho(indp(j,ind))=rho(indp(j,ind))+vol2(j)
end if
end do
endif
if(ilevel==cic_levelmax)then
do j=1,np
! check for DM
if ( ok(j) .and. is_DM(fam(j)) ) then
rho_top(indp(j,ind))=rho_top(indp(j,ind))+vol2(j)
end if
end do
endif
do j=1,np
vol2(j)=vol(j,ind)
end do
! Remove test particles for static runs
if(static)then
do j=1,np
ok(j)=ok(j).and.mmm(j)>0.0
end do
endif
! Keep only DM particle with a mass below the mass cut
if(mass_cut_refine>0.0)then
do j=1,np
if ( is_DM(fam(j)) ) then
ok(j)=ok(j) .and. mmm(j) < mass_cut_refine
endif
end do
endif
! Rescale the mass by mass_sph for baryon particles
if(star)then
do j=1,np
if ( is_not_DM(fam(j)) ) then
vol2(j) = vol2(j)*mmm(j)/mass_sph
endif
end do
endif
if(cic_levelmax==0.or.ilevel<cic_levelmax)then
do j=1,np
if(ok(j))then
phi(indp(j,ind))=phi(indp(j,ind))+vol2(j)
end if
end do
else if(ilevel>=cic_levelmax)then
do j=1,np
if ( ok(j) .and. is_not_DM(fam(j)) ) then
phi(indp(j,ind))=phi(indp(j,ind))+vol2(j)
end if
end do
endif
! Always refine sinks to the maximum level
! by setting particle number density above m_refine(ilevel)
if(sink_refine)then
do j=1,np
if ( is_cloud(fam(j)) ) then
! if (direct_force_sink(-1*idp(ind_part(j))))then
phi(indp(j,ind))=phi(indp(j,ind))+m_refine(ilevel)
! endif
end if
end do
end if
end do
end subroutine cic_amr
!###########################################################
!###########################################################
!###########################################################
!###########################################################
subroutine multipole_fine(ilevel)
use amr_commons
use hydro_commons
use poisson_commons
use mpi_mod
implicit none
integer::ilevel
!-------------------------------------------------------------------
! This routine compute array rho (source term for Poisson equation)
! by first reseting array rho to zero, then
! by affecting the gas density to leaf cells, and finally
! by performing a restriction operation for split cells.
! For pure particle runs, the restriction is not necessary and the
! routine only set rho to zero. On the other hand, for the Multigrid
! solver, the restriction is necessary in any case.
!-------------------------------------------------------------------
integer ::ind,i,ncache,igrid,ngrid,iskip,nx_loc
integer ::idim,nleaf,nsplit,ix,iy,iz,iskip_son,ind_son,ind_grid_son,ind_cell_son
integer,dimension(1:nvector),save::ind_grid,ind_cell,ind_leaf,ind_split
real(dp),dimension(1:nvector,1:ndim),save::xx
real(dp),dimension(1:nvector),save::dd
real(kind=8)::dx,dx_loc,scale,vol_loc,mm
real(dp),dimension(1:3)::skip_loc
real(dp),dimension(1:twotondim,1:3)::xc
if(numbtot(1,ilevel)==0)return
if(verbose)write(*,111)ilevel
! Mesh spacing in that level
dx=0.5D0**ilevel
nx_loc=(icoarse_max-icoarse_min+1)
skip_loc=(/0.0d0,0.0d0,0.0d0/)
if(ndim>0)skip_loc(1)=dble(icoarse_min)
if(ndim>1)skip_loc(2)=dble(jcoarse_min)
if(ndim>2)skip_loc(3)=dble(kcoarse_min)
scale=boxlen/dble(nx_loc)
dx_loc=dx*scale
vol_loc=dx_loc**ndim
do ind=1,twotondim
iz=(ind-1)/4
iy=(ind-1-4*iz)/2
ix=(ind-1-2*iy-4*iz)
if(ndim>0)xc(ind,1)=(dble(ix)-0.5D0)*dx
if(ndim>1)xc(ind,2)=(dble(iy)-0.5D0)*dx
if(ndim>2)xc(ind,3)=(dble(iz)-0.5D0)*dx
end do
! Initialize fields to zero
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
do i=1,active(ilevel)%ngrid
unew(active(ilevel)%igrid(i)+iskip,1)=0.0D0
end do
do idim=1,ndim
do i=1,active(ilevel)%ngrid
unew(active(ilevel)%igrid(i)+iskip,idim+1)=0.0D0
end do
end do
end do
! Compute mass multipoles in each cell
ncache=active(ilevel)%ngrid
do igrid=1,ncache,nvector
ngrid=MIN(nvector,ncache-igrid+1)
do i=1,ngrid
ind_grid(i)=active(ilevel)%igrid(igrid+i-1)
end do
! Loop over cells
do ind=1,twotondim
iskip=ncoarse+(ind-1)*ngridmax
! Gather cell indices
do i=1,ngrid
ind_cell(i)=ind_grid(i)+iskip
end do
! Gather leaf cells and compute cell centers
nleaf=0
do i=1,ngrid
if(son(ind_cell(i))==0)then
nleaf=nleaf+1
ind_leaf(nleaf)=ind_cell(i)
do idim=1,ndim
xx(nleaf,idim)=(xg(ind_grid(i),idim)+xc(ind,idim)-skip_loc(idim))*scale
end do
end if
end do
! Compute gas multipole for leaf cells only
if(hydro)then
do i=1,nleaf
mm=max(uold(ind_leaf(i),1),smallr)*vol_loc
unew(ind_leaf(i),1)=unew(ind_leaf(i),1)+mm
end do
do idim=1,ndim
do i=1,nleaf
mm=max(uold(ind_leaf(i),1),smallr)*vol_loc
unew(ind_leaf(i),idim+1)=unew(ind_leaf(i),idim+1)+mm*xx(i,idim)
end do
end do
endif
! Add analytical density profile for leaf cells only
if(gravity_type < 0)then
! Call user defined routine rho_ana
call rho_ana(xx,dd,dx_loc,nleaf)
! Scatter results to array phi
do i=1,nleaf
unew(ind_leaf(i),1)=unew(ind_leaf(i),1)+dd(i)*vol_loc
end do
do idim=1,ndim
do i=1,nleaf
mm=dd(i)*vol_loc
unew(ind_leaf(i),idim+1)=unew(ind_leaf(i),idim+1)+mm*xx(i,idim)
end do
end do
end if
! Gather split cells
nsplit=0
do i=1,ngrid
if(son(ind_cell(i))>0)then
nsplit=nsplit+1
ind_split(nsplit)=ind_cell(i)
end if
end do
! Add children multipoles
do ind_son=1,twotondim
iskip_son=ncoarse+(ind_son-1)*ngridmax
do i=1,nsplit