-
Notifications
You must be signed in to change notification settings - Fork 0
/
fastapi.nix
193 lines (172 loc) · 5.22 KB
/
fastapi.nix
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
{
config,
host,
inputs,
lib,
pkgs,
...
}:
let
inherit (lib)
elemAt
filterAttrs
flatten
getExe
mapAttrs
mapAttrs'
mapAttrsToList
mkEnableOption
mkIf
mkOption
nameValuePair
splitString
types
;
lib' = (import ../lib.nix) { inherit lib pkgs; };
cfg = config.my-nixos.fastapi;
eachSite = filterAttrs (hostname: cfg: cfg.enable) cfg.sites;
stateDir = hostname: "/var/lib/${hostname}/fastapi";
siteOpts = {
options = with types; {
enable = mkEnableOption "FastAPI app";
port = mkOption {
description = "Listening port.";
example = 8000;
type = port;
};
ssl = mkOption {
description = "Whether to enable SSL (https) support.";
type = bool;
};
user = mkOption {
description = "Username for app owner";
type = str;
default = null;
};
};
};
fastapiPkgs =
hostname: inputs.${elemAt (splitString "." hostname) 0}.packages.${host.system}.fastapi;
envs = mapAttrs (
hostname: cfg:
(lib'.mkEnv hostname {
ALLOW_ORIGINS = "'[\"${if cfg.ssl then "https" else "http"}://${hostname}\"]'";
DB_DSN = "postgresql+psycopg2://${hostname}@:5432/${hostname}";
ENV = "production";
HOSTNAME = hostname;
LOG_LEVEL = "error";
SECRETS_DIR = builtins.dirOf config.age.secrets."${hostname}/secret_key".path;
SSL = if cfg.ssl then "true" else "false";
STATE_DIR = stateDir hostname;
})
) eachSite;
bins = mapAttrs (
hostname: cfg:
((fastapiPkgs hostname).bin.overrideAttrs {
env = envs.${hostname};
name = "${hostname}-manage";
})
) eachSite;
in
{
options.my-nixos.fastapi = with types; {
sites = mkOption {
type = attrsOf (submodule siteOpts);
default = { };
description = "Definition of per-domain FastAPI apps to serve.";
};
};
config = mkIf (eachSite != { }) {
environment.systemPackages = mapAttrsToList (hostname: bin: bin) bins;
age.secrets = mapAttrs' (
hostname: cfg:
(nameValuePair "${hostname}/secret_key" {
file = ../secrets/webapp-key-${hostname}.age;
owner = cfg.user;
group = cfg.user;
})
) eachSite;
users = lib'.mergeAttrs (hostname: cfg: {
users.${cfg.user} = {
isSystemUser = true;
group = cfg.user;
};
groups.${cfg.user} = { };
}) eachSite;
my-nixos.postgresql = mapAttrs (hostname: cfg: { ensure = true; }) eachSite;
systemd.tmpfiles.rules = flatten (
mapAttrsToList (hostname: cfg: [
"d '${stateDir hostname}' 0750 ${cfg.user} ${cfg.user} - -"
"Z '${stateDir hostname}' 0750 ${cfg.user} ${cfg.user} - -"
]) eachSite
);
services.nginx.virtualHosts = mapAttrs (hostname: cfg: {
serverName = hostname;
forceSSL = cfg.ssl;
enableACME = cfg.ssl;
locations."/api" = {
recommendedProxySettings = true;
proxyPass = "http://localhost:${toString cfg.port}";
};
}) eachSite;
systemd.services = lib'.mergeAttrs (hostname: cfg: {
"${hostname}-fastapi" = {
description = "serve ${hostname}-fastapi";
serviceConfig = {
ExecStart = "${(fastapiPkgs hostname).app.dependencyEnv}/bin/uvicorn app.main:fastapi --host localhost --port ${toString cfg.port}";
User = cfg.user;
Group = cfg.user;
EnvironmentFile = "${envs.${hostname}}";
};
wantedBy = [ "multi-user.target" ];
};
"${hostname}-fastapi-migrate" = {
path = [ pkgs.bash ];
description = "migrate ${hostname}-fastapi";
serviceConfig = {
Type = "oneshot";
ExecStart = "${(fastapiPkgs hostname).bin}/bin/manage migrate";
User = cfg.user;
Group = cfg.user;
EnvironmentFile = "${envs.${hostname}}";
};
};
"${hostname}-pgsql-dump" = {
description = "dump a snapshot of the postgresql database";
serviceConfig = {
Type = "oneshot";
ExecStart = "${getExe pkgs.bash} -c '${pkgs.postgresql}/bin/pg_dump -U ${hostname} ${hostname} > ${stateDir hostname}/dbdump.sql'";
User = cfg.user;
Group = cfg.user;
};
};
"${hostname}-pgsql-restore" = {
description = "restore postgresql database from snapshot";
serviceConfig = {
Type = "oneshot";
ExecStart = "${getExe pkgs.bash} -c '${pkgs.postgresql}/bin/psql -U ${hostname} ${hostname} < ${stateDir hostname}/dbdump.sql'";
User = cfg.user;
Group = cfg.user;
};
};
}) eachSite;
systemd.timers = lib'.mergeAttrs (hostname: cfg: {
"${hostname}-pgsql-dump" = {
description = "Scheduled PostgreSQL database dump";
wantedBy = [ "timers.target" ];
timerConfig = {
OnCalendar = "daily";
Unit = "${hostname}-pgsql-dump";
};
};
}) eachSite;
my-nixos.backup."backup.ahbk".paths = flatten (
mapAttrsToList (hostname: cfg: [ (stateDir hostname) ]) eachSite
);
system.activationScripts = mapAttrs (hostname: cfg: {
text = ''
${pkgs.systemd}/bin/systemctl start ${hostname}-fastapi-migrate
'';
}) eachSite;
};
}