forked from kohler/click
-
Notifications
You must be signed in to change notification settings - Fork 0
/
click-mkclgw.pl
1773 lines (1503 loc) · 41.7 KB
/
click-mkclgw.pl
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#!/usr/bin/perl
#
#
# $Id: click-mkclgw.pl,v 1.13 2005/03/06 23:32:29 max Exp $
#
# click-mkclgw
#
# Click Make Cluster Gateway
#
# Imagine a cluster of servers that have a small block of IPs
# externally and a whole boatload of IPs internally. This script
# accepts input configuration files, and outputs Click configurations
# for managing packet rewriting for the cluster. Incudes
# NATing and load balancing functionality.
#
# Max Krohn
#
#
use strict;
#
# CLGW::Base
#
# Base class for all CLGW data compontents (not parser components)
#
package CLGW::Base;
sub new {
my $class = shift;
my $self = { @_ };
bless $self, $class;
return $self;
}
sub iscluster { return 0; }
sub clust_full_size { return -1; }
sub active_nodes { return (); }
sub ith { return undef; }
#
# CLGW::Base::range_to_arr
#
# Parse a range from the string of the form "[1-4,5-7,13]" and outputs
# an array of the form (1,2,3,4,5,6,7,13). Also returns a inclusion
# map for the array, so that you can quickly lookup which elements
# are in the set.
#
sub range_to_arr {
my ($self, $input) = @_;
my @terms = split /,/ , $input;
my @lst;
my $err = 0;
foreach my $term (@terms) {
if ($term =~ /^\d+$/) {
push @lst, $term;
} elsif ($term =~ /^(\d+)-(\d+)$/ ) {
my $lim = $2;
for (my $i = $1; $i <= $lim; $i++) {
push @lst, $i;
}
} else {
warn "Bad range specification: $input\n";
$err = 1;
}
}
return (undef, undef) if $err;
my @slst = sort { $a <=> $b } @lst;
my $ret_map = {};
my $rarr = [];
foreach my $i (@slst) {
unless ($ret_map->{$i}) {
push @$rarr, $i;
$ret_map->{$i} = 1;
}
}
return ($rarr, $ret_map);
}
#
# CLGW::Cluster - base class for Cluster data components
#
package CLGW::Cluster;
sub iscluster { return 1; }
package CLGW::Const;
#
# Woefully inadequate list of ports to specify in a config file
# Special ports "napt", "info" and "param" have been hacked on --
# they specify config file groups more than they specify ports.
#
$CLGW::Const::PORT_ALL = 0;
$CLGW::Const::PORT_NAPT = 1;
$CLGW::Const::INFO = 2;
$CLGW::Const::PARAM = 3;
$CLGW::Const::PORT_HTTP = 4;
$CLGW::Const::PORT_SSH = 5;
$CLGW::Const::PORT_SFS = 6;
$CLGW::Const::PORT_HTTPS = 7;
$CLGW::Const::PORT_TELNET = 8;
#
# Different types of definable addressing schemes
#
$CLGW::Const::ADDR_ENET = 0;
$CLGW::Const::ADDR_IPNET = 1;
$CLGW::Const::ADDR_IP = 2;
$CLGW::Const::ADDR_IP_CLUSTER = 3;
$CLGW::Const::NAPT_PORT_RANGE = "50000-65535";
$CLGW::Const::TAB_IN = 45; # formatting constant
%CLGW::Const::PORTMAP = ( "*" => $CLGW::Const::PORT_ALL,
# not ports per-se, but can refer
# to parts of the configuration file,
# in much the same we're using ports
"napt" => $CLGW::Const::PORT_NAPT,
"info" => $CLGW::Const::INFO,
"default" => $CLGW::Const::INFO,
"param" => $CLGW::Const::PARAM,
# TCP ports/services open
"www" => $CLGW::Const::PORT_HTTP,
"http" => $CLGW::Const::PORT_HTTP,
"ssh" => $CLGW::Const::PORT_SSH,
"sfs" => $CLGW::Const::PORT_SFS,
"https" => $CLGW::Const::PORT_HTTPS,
"telnet" => $CLGW::Const::PORT_TELNET );
%CLGW::Const::R_PORTMAP = ( $CLGW::Const::PORT_SSH => "ssh",
$CLGW::Const::PORT_HTTP => "www",
$CLGW::Const::PORT_HTTPS => "https",
$CLGW::Const::PORT_TELNET => "telnet",
$CLGW::Const::PORT_SFS => 4 );
#
# strings of how these parameters will be output to the
# Click configuration
#
%CLGW::Const::LABEL_MAP = qw [ EXTERNAL extern
INTERNAL intern
NEXTHOP extern_next_hop
INTDNS dns_int ];
#
# CLGW::Parser
#
package CLGW::Parser;
@CLGW::Parser::ISA = qw [ CLGW::Base ] ;
sub new {
my $self = CLGW::Base::new (@_);
$self->{_eof} = 0;
return $self;
}
#
# CLGW::Parser::nxtln
#
# Pulls a line from the input file (at this point, can only
# be standard input).
#
sub nxtln {
my ($self) = @_;
my $line;
while (($line = <>)) {
$line =~ s/#.*//;
if ($line =~ /\S/) {
chomp ($line);
return $line;
}
}
$self->{_eof} = 1;
return undef;
}
sub parse_error {
my ($self, $e, $ln) = @_;
$ln = $self->{_eof} ? "EOF" : $self->{_line_now} unless $ln;
die $ln . ": " . $e . "\n";
}
#
# CLGW::Parser::parse_rule_group
#
# <rule-group> := {<port-specifier>;
# <rule1>;
# <rule2>;
# .
# .
# <rulen>}
#
# <port-specifier> := (<port1>|<port2>| .... ) |
# (info) |
# (napt) |
# (param)
#
# Returns: 0 on success / -1 on EOF
#
sub parse_rule_group {
my ($self, $arr_out) = @_;
my $line = $self->nxtln ();
$self->{_line_now} = $.;
return -1 unless $line;
$self->parse_error ("Expected rule start") unless $line =~ s/^\s*\{// ;
my $n;
my $done = 0;
$done = 1 if $line =~ s/\}.*$// ;
while ($done == 0 and ($n = $self->nxtln ())) {
$line .= $n;
$done = 1 if $line =~ s/\}.*$// ;
}
$self->parse_error ("Rule starting at line $self->{_line_now} unclosed!")
unless $done;
my @terms = split /\s*;\s*/, $line;
my $srv_raw = shift @terms;
$self->parse_error ("Expected port/service type!")
unless $srv_raw =~ /^\((.*)\)$/ ;
my $ports = $1;
my @port_str_arr = split /\|/, $ports;
my @port_arr;
foreach my $port_str (@port_str_arr) {
my $port = $CLGW::Const::PORTMAP{$port_str};
$self->parse_error ("Unrecognized port/service: $port_str")
unless defined $port;
push @port_arr, $port;
}
$self->parse_error ("empty rule encountered!") unless $#terms >= 0;
foreach my $term (@terms) {
my $rule = $self->parse_rule ($term, \@port_arr);
if (ref ($rule) eq "ARRAY") {
push @$arr_out, @$rule;
} else {
push @$arr_out, $rule;
}
}
return 0;
}
#
# CLGW::Parser::parse_rule
#
# <rule> := <label> <addr1> <addr2> ...
#
sub parse_rule {
my ($self, $term, $port_arr) = @_;
my @factors = split /\s+/, $term;
$self->parse_error ("unlabeled entry encountered") unless $#factors >= 0;
my $label = $self->parse_cluster_label (shift @factors);
$self->parse_error ("useless entry encountered") unless $#factors >= 0;
my @addrs;
foreach my $addr (@factors) {
push @addrs, $self->parse_addr ($addr);
}
my $ret;
if ($#addrs == 2 and
$self->port_typ ($port_arr, $CLGW::Const::PORT_NAPT) and
$addrs[0]->typ () eq "ip" and
$addrs[1]->typ () eq "ip" and
$addrs[2]->typ () eq "net" and
!$label->iscluster () ) {
#
# NAPT cluster, not accessible from the outside:
#
# <label> <ip-addr> <ip-addr> <net-addr>
#
$ret = CLGW::Rule::NAPT->new ( "_ports" => [ @$port_arr ],
"_label" => $label,
"_ext_addr" => $addrs[0],
"_int_addr" => $addrs[1],
"_nat_net" => $addrs[2] );
} elsif ($#addrs == 0 and $addrs[0]->typ eq "ip" and
$self->port_typ ($port_arr, $CLGW::Const::INFO) and
!$label->iscluster () ) {
#
# Assign a label to an IP address
#
# <label> <ip-addr>
#
$ret = CLGW::Rule::IPLabel->new ( "_label" => $label,
"_ip" => $addrs[0] );
} elsif ($#addrs == 0 and $addrs[0]->typ eq "param" and
$self->port_typ ($port_arr, $CLGW::Const::PARAM) and
!$label->iscluster () ) {
#
# Set a parameter
#
# <name> <value>
#
$ret = CLGW::Rule::Param->new ( "_label" => $label,
"_param" => $addrs[0] );
} elsif ($#addrs == 2 and
!$label->iscluster () and
$addrs[0]->typ () eq "ip" and
$addrs[1]->typ () eq "net" and
$addrs[2]->typ () eq "eth") {
#
# Specify a Click-style AddrInfo
#
# <label> <ip-addr> <net-addr> <eth>
#
$ret = CLGW::Rule::IFace->new ( "_label" => $label,
"_ip" => $addrs[0],
"_net" => $addrs[1],
"_eth" => $addrs[2] );
} elsif ($#addrs == 1 and
!$label->iscluster () and
$addrs[0]->typ () eq "ip" and
$addrs[1]->typ () eq "eth" and
$self->port_typ ($port_arr, $CLGW::Const::INFO) ) {
#
# Specify a Click-style AddrInfo
#
# <label> <ip-addr> <eth-addr>
#
$ret = CLGW::Rule::IFace->new ("_label" => $label,
"_ip" => $addrs[0],
"_eth" => $addrs[1] );
} elsif ($#addrs == 0 and
!$label->iscluster () and
$addrs[0]->typ () eq "eth" and
$self->port_typ ($port_arr, $CLGW::Const::INFO)) {
#
# Specify a Click-style AddrInfo
#
# <label> <eth-addr>
#
$ret = CLGW::Rule::IFace->new ("_label" => $label,
"_eth" => $addrs[0] );
} elsif (($#addrs == 1 or $#addrs == 3) and
$addrs[0]->is_ip () and
$addrs[1]->is_ip () ) {
my $ext_addr = $addrs[0];
my $int_addr = $addrs[1];
#
# load-balanced napt cluster
#
# <clust-label> <ip-addr> <ip-addrs> [ <ip-addr> <ip-net> ]
# Cluster Label ExtIP IntIPS IntGW NAPTNet
#
if ($label->iscluster () and !$ext_addr->iscluster ()) {
$self->parse_error ("Malformed load-balanced cluster; " .
"internal IP range is not a cluster")
unless $int_addr->iscluster ();
$self->parse_error ("Cluster size mismatch") unless
$label->clust_full_size () ==
$int_addr->clust_full_size ();
$ret = CLGW::Rule::LBNAPT->new ("_ports" => [ @$port_arr ],
"_label" => $label,
"_int_clust" => $int_addr,
"_ext_addr" => $ext_addr );
if ($#addrs == 3) {
my $int_gw = $addrs[2];
my $nat_net = $addrs[3];
my $typ;
$self->parse_error ("4th argument is Internal Cluster Addr".
"and should be a simple IP Address")
unless $int_gw->typ () eq "ip" ;
$self->parse_error ("5th argument is a $typ but" .
"should be a network range/ipnet")
unless ($typ = $nat_net->typ ()) eq "net";
$ret->{_nat_net} = $nat_net;
$ret->{_int_addr} = $int_gw;
}
$self->parse_error ("Bad port specification")
unless $ret->fix_ports ();
} elsif (!$label->iscluster () and !$ext_addr->iscluster () and
!$int_addr->iscluster () and $#addrs == 1) {
#
# simple NAT resolution
#
$ret = CLGW::Rule::Nat->new ("_ports" => [ @$port_arr ],
"_label" => $label,
"_int_addr" => $int_addr,
"_ext_addr" => $ext_addr );
$self->parse_error ("Bad port specification")
unless $ret->fix_ports ();
} elsif ($label->iscluster () and $ext_addr->iscluster () and
$int_addr->iscluster () and $#addrs == 1) {
my $sz = $label->clust_full_size ();
$self->parse_error ("NAT group size mismatch") unless
(($sz == $ext_addr->clust_full_size ()) and
($sz == $int_addr->clust_full_size ()));
#
# array of simple NAT resolutions
#
$ret = [];
my @active = $label->active_nodes ();
foreach my $i (@active) {
my $tlab = $label->ith ($i);
my $tint = $int_addr->ith ($i);
my $text = $ext_addr->ith ($i);
my $n = CLGW::Rule::Nat->new ("_ports" => [ @$port_arr ],
"_label" => $tlab,
"_int_addr" => $tint,
"_ext_addr" => $text );
$self->parse_error ("Bad port specification")
unless $n->fix_ports ();
push @$ret, $n;
}
} else {
$self->parse_error ("Unrecognized term construction: $term");
}
} else {
$self->parse_error ("Unrecognized term construction: $term");
}
return $ret;
}
sub port_typ {
my ($self, $port_arr, $typ) = @_;
return ($#$port_arr == 0 and $port_arr->[0] == $typ);
}
#
# CLGW::Parser::parse_addr
#
# Classifies addresses as either Ethernet, IP, IPNet or IP
# Cluster/Range types.
#
sub parse_addr {
my ($self, $input) = @_;
if ($input =~ /^([a-fA-F0-9]{2}\:){5}[a-fA-F0-9]{2}$/) {
return CLGW::Addr::Eth->new ("_addr" => $input );
}
return CLGW::Addr::Param->new ("_value" => $input)
unless $input =~ /^((\d{1,3}\.){3})(.*)$/;
my $prfx = $1;
my $sffx = $3;
my $ret;
if ($sffx =~ /^\[(.*)\]$/ ) {
my ($arr, $map) = $self->range_to_arr ($1);
$ret = CLGW::Addr::Cluster->new ("_prefix" => $prfx,
"_range" => [ @$arr ]);
} elsif ($sffx =~ m!^(\d{1,3})(/(\d{1,2}))?$! ) {
my $part4 = $1;
my $net = $3;
my $addr = $prfx . $part4;
if ($net) {
$self->parse_error ("Bad subnet id: $net")
unless $net >=8 and $net <= 32;
$ret = CLGW::Addr::Net->new ("_addr" => $addr,
"_class" => $net );
} else {
$ret = CLGW::Addr::IP->new ("_addr" => $addr);
}
} else {
$self->parse_error("Bad address: $input");
}
return $ret;
}
#
# CLGW::Parser::parse_cluster_label
#
# Cluster labels consist of a label, a group of included IDs,
# and a group of excluded IDs, which should be a subset of the
# included ids. Examples include:
#
# ws[0-14]/[4,9,10-13]
# img[0-4]
# cgi[1,2,3]
#
sub parse_cluster_label {
my ($self, $input) = @_;
#
# note, no "-" characters allowed in labels, since Click
# does not allow "-" in labels.
#
return undef unless
$input =~ m!^([a-zA-Z0-9_]+)(\[(.*?)\](/\[(.*?)\])?)?$!;
my $lab = $1;
my $incl = $3;
my $excl = $5;
my $ret ;
if ($incl) {
$ret = CLGW::Label::Cluster->new ("_label" => $lab,
"_include" => $incl,
"_exclude" => $excl );
} else {
$ret = CLGW::Label->new ("_label" => $lab);
}
$self->parse_error ("Bad cluster label specification") unless $ret;
return $ret;
}
package CLGW::Addr;
@CLGW::Addr::ISA = qw [ CLGW::Base ];
sub typ { return "generic"; }
sub is_ip { return 0; }
sub dump {
my ($self) = @_;
warn ref ($self) , ": " , $self->{_addr} , "\n";
}
sub str { return undef };
package CLGW::Addr::Param;
@CLGW::Addr::Param::ISA = qw [ CLGW::Addr ];
sub typ { return "param"; }
sub str {
my ($self) = @_;
return $self->{_value};
}
package CLGW::Addr::Net;
@CLGW::Addr::Net::ISA = qw [ CLGW::Addr ];
sub typ { return "net" ; }
sub str {
my ($self) = @_;
return $self->{_addr} . "/" . $self->{_class};
}
package CLGW::Addr::IP;
@CLGW::Addr::IP::ISA = qw [ CLGW::Addr ];
sub typ { return "ip"; }
sub is_ip { return 1; }
sub str {
my ($self) = @_;
return $self->{_addr};
}
package CLGW::Addr::Eth;
@CLGW::Addr::Eth::ISA = qw [ CLGW::Addr ];
sub str {
my ($self) = @_;
return $self->{_addr};
}
sub typ { return "eth"; }
package CLGW::Addr::Cluster;
@CLGW::Addr::Cluster::ISA = qw [ CLGW::Cluster CLGW::Addr ];
sub typ { return "cluster"; }
sub is_ip { return 1; }
sub ith {
my ($self, $i) = @_;
my $id = $self->{_range}->[$i];
return CLGW::Addr::IP->new ("_addr" => $self->{_prefix} . $id,
"_clustid" => $i);
}
sub clust_full_size {
my ($self) = @_;
return $#{$self->{_range}} + 1;
}
sub to_machines {
my ($self) = @_;
my @arr;
foreach my $r (@{$self->{_range}}) {
my $addr = $self->{_prefix} . $r;
push @arr, CLGW::Add::IP->new ("_addr" => $addr,
"_clustid" => $r );
}
return @arr;
}
sub dump {
my ($self) = @_;
warn ref ($self), ":\n";
my @mach = $self->to_machines ();
foreach my $m (@mach) { $m->dump (); }
}
package CLGW::Label;
@CLGW::Label::ISA = qw [ CLGW::Base ];
sub str {
my ($self) = @_;
return $self->{_label};
}
package CLGW::Label::Cluster;
@CLGW::Label::Cluster::ISA = qw [ CLGW::Cluster CLGW::Label ] ;
sub clust_full_size {
my ($self) = @_;
return $#{$self->{_inc_arr}} + 1;
}
#
# CLGW::Label::Cluster::active_nodes
#
# Outputs a list of IDs that correspond to active nodes in the cluster.
#
sub active_nodes {
my ($self) = @_;
my $sz = $self->clust_full_size ();
my @ret = ();
for (my $i = 0; $i < $sz; $i++) {
my $id = $self->{_inc_arr}->[$i];
push @ret, $i unless $self->{_excl_map}->{$id};
}
return @ret;
}
sub ith {
my ($self, $i) = @_;
my $id = $self->{_inc_arr}->[$i];
return CLGW::Label->new ("_label" => $self->{_label} . $id );
}
#
# CLGW::Label::Cluster::new
#
# Does error checking to make sure that the exlcuded list is indeed
# a subset of the included list.
#
sub new {
my $self = CLGW::Base::new ( @_ );
($self->{_inc_arr}, $self->{_inc_map})
= $self->range_to_arr ( $self->{_include} );
($self->{_excl_arr}, $self->{_excl_map})
= $self->range_to_arr ( $self->{_exclude} );
my $err = 0;
foreach my $l (qw [ _inc_arr _inc_map _excl_arr _excl_map] ) {
$err = 1 unless ($self->{$l});
}
foreach my $a (@{$self->{_excl_arr}}) {
unless ($self->{_inc_map}->{$a}) {
warn "Cannot exclude $self->{_label}$a; not included!\n";
$err = 1;
}
}
return $err ? undef : $self;
}
#
# CLGW::Rule
#
# Generic rule; base class for more useful rules.
#
package CLGW::Rule;
@CLGW::Rule::ISA = qw [ CLGW::Base ];
sub is_napt { return 0; }
sub addr_info { return undef; }
sub lb_mapper { return undef; }
sub get_int_ips {}
sub get_ext_ips {}
sub ip_from_extern_classify { return undef; }
sub tcp_from_extern_classify { return undef; }
sub rewriter_pattern { return undef; }
sub ip_rewriter { return undef; }
sub rewriter_plumbing { return undef; }
sub get_intern_src { return undef; }
sub from_int_plumbing {}
#
# CLGW::Rule::connect
#
# A static method; takes element 1 (e1) port 1 (p1), and hooks
# it up to element 2, port 2, addind comment (com) to the end of the
# line. Also tries to do some text alignment for purely asthetic
# reasons.
#
sub connect {
my ($self, $e1, $p1, $e2, $p2, $com) = @_;
my $p2_str = defined($p2) ? "[$p2]" : "";
my $s = $e1 . "[$p1] -> " . $p2_str . $e2 . ";";
my $len = $CLGW::Const::TAB_IN - length ($s) ;
foreach (1 .. $len) { $s .= " "; }
$s .= " // $com" if $com;
print $s, "\n";
}
#
# CLGW::Rule::discard
#
# As above, but throws out all packets coming out of the given
# port.
#
sub discard {
my ($self, $e1, $p1, $com) = @_;
my $s = $e1 . "[$p1] -> Discard;";
my $len = $CLGW::Const::TAB_IN - length ($s) ;
foreach (1 .. $len) { $s .= " "; }
$s .= " // $com" if $com;
print $s, "\n";
}
#
# CLGW::Rule::is_internal_dns
#
# Currently broken DNS feature.
#
sub is_internal_dns {
my ($self) = @_;
return $self->labelstr () eq "INTDNS";
}
sub labelstr {
my ($self) = @_;
return $self->{_label}->str ();
}
#
# CLGW::Rule::int_lab
#
# Internal label for this rule..
#
sub int_lab {
my ($self) = @_;
return $self->labelstr () . "_int";
}
sub labelstr_gw_override {
my ($self) = @_;
return $self->labelstr ();
}
sub in_pat {
my ($self) = @_;
return $self->labelstr_gw_override () . "_in";
}
sub out_pat {
my ($self) = @_;
return $self->labelstr_gw_override () . "_out";
}
sub tcp_classifier_label {
my ($self) = @_;
my $prfx = $self->labelstr_gw_override ();
return $prfx . "_ip_from_extern";
}
sub mapped_label {
my ($self) = @_;
my $lab = $self->labelstr ();
my $lab2 = $CLGW::Const::LABEL_MAP{$lab};
$lab = $lab2 if defined($lab2);
return $lab;
}
#
# CLGW:Rule::fix_ports
#
# Converts ports from our input file format into Click style
# port combinations.
#
sub fix_ports {
my ($self) = @_;
my @ports;
foreach my $p (@{$self->{_ports}}) {
my $s = $CLGW::Const::R_PORTMAP{$p};
if ($p == $CLGW::Const::PORT_ALL) {
$self->{_port_str} = "*";
return 1;
}
return 0 unless $s;
push @ports, $s;
}
$self->{_port_str} = join " or ", @ports;
return 1;
}
#
# class for rules regarding this cluster's interfaces..
#
package CLGW::Rule::IFace;
@CLGW::Rule::IFace::ISA = qw [ CLGW::Rule ];
sub addr_info {
my ($self) = @_;
my $lab = $self->mapped_label ();
my @elems = ( $lab );
foreach my $prt (qw [ _ip _net _eth ] ) {
my $x = $self->{$prt};
push @elems, $x->str () if $x;
}
return join "\t", @elems;
}
sub is_external_iface {
my ($self) = @_;
return $self->labelstr () eq "EXTERNAL";
}
sub get_int_ips {
my ($self, $outarr) = @_;
return unless $self->labelstr () eq "INTERNAL";
push @$outarr, $self->mapped_label () . ":ip";
}
sub get_ext_ips {
my ($self, $outarr) = @_;
return unless $self->is_external_iface ;
push @$outarr, $self->mapped_label () . ":ip";
}
sub ip_from_extern_classify {
my ($self, $port) = @_;
return undef unless $self->is_external_iface ;
$self->{_ip_from_extern_port} = $port;
return $self->mapped_label ();
}
sub labelstr_gw_override {
my ($self) = @_;
if ($self->{_label_override}) {
return $self->{_label_override}
} else {
return "gw";
}
}
sub tcp_from_extern_classify {
my ($self) = @_;
return undef unless $self->is_external_iface ;
my $x = $self->tcp_classifier_label ();
my $p = $self->{_ip_from_extern_port};
my @inputs = ( "src tcp port ftp",
"tcp or udp",
"-");
$self->{_tcp_portmap}->{_ftp} = 0;
$self->{_tcp_portmap}->{_tcp_or_udp} = 1;
$self->{_tcp_portmap}->{_def} = 2;
my $istr = join ",\n", map { "\t$_" } @inputs;
print "$x :: IPClassifier(\n$istr\n);\nip_from_extern[$p] -> $x;\n\n";
}
sub rewriter_pattern {
my ($self) = @_;
return undef unless $self->is_external_iface ;
my @els = ( $self->out_pat (),
$self->mapped_label (),
$CLGW::Const::NAPT_PORT_RANGE,
"-",
"-" );
return join (" ", @els);
}
sub ip_rewriter {
my ($self, $port, $map) = @_;
return undef unless $self->is_external_iface ;
my @elems = ( "pattern",
$self->out_pat (),
0,
1);
$self->{_out_pat_port} = $port;
return join (" ", @elems);
}
sub rewriter_plumbing {
my ($self, $port_map, $map) = @_;
return undef unless $self->is_external_iface ;
my $cl = $self->tcp_classifier_label ();
$self->connect ($cl, $self->{_tcp_portmap}->{_ftp},
"tcp_rw", 1, "FTP control traffic");
$self->connect ($cl, $self->{_tcp_portmap}->{_tcp_or_udp},
"rw", $port_map->{_ext_to_gw},
"all TCP/UDP to GW");
$self->discard ($cl, 2, "discard everything else");
print "\n";
}
package CLGW::Rule::NatBase;
@CLGW::Rule::NatBase::ISA = qw [ CLGW::Rule ];
sub accepting { return 0; }
sub from_int_plumbing {
my ($self, $in, $out) = @_;
my ($p1, $p2);
if (defined ($p1 = $self->{_intern_src_out_port}) and
defined ($p2 = $self->{_out_pat_port})) {
$self->connect ($in, $p1, $out, $p2);
}
}
sub tcp_from_extern_classify {
my ($self) = @_;
my $x = $self->tcp_classifier_label ();
my $p = $self->{_ip_from_extern_port};
my $ports = $self->{_port_str};
my $shft = 0;
my @inputs = ( "src tcp port ftp",
"tcp or udp",
"-" );
my $prt = 0;
if (!($ports eq "*") and $self->accepting ()) {
unshift @inputs, "dst tcp $ports";
$self->{_fw} = 1;
$self->{_tcp_portmap}->{_accepting} = $prt ++;
}
foreach my $pn (qw [ _ftp _tcp_or_udp _def ] ) {
$self->{_tcp_portmap}->{$pn} = $prt ++;
}
my $port_str = join ",\n", map {"\t$_" } @inputs;
print "$x :: IPClassifier (\n$port_str\n);\nip_from_extern[$p] -> $x;\n\n";
}
sub rewriter_plumbing {
my ($self, $port_map, $map) = @_;
my $cl = $self->tcp_classifier_label ();
my ($p1, $p2);
if (defined ($p1 = $self->{_tcp_portmap}->{_accepting}) and
defined ($p2 = $self->{_in_pat_port})) {
$self->connect ($cl, $p1, "rw", $p2, "accepting incoming connections");
}
$self->connect ($cl, $self->{_tcp_portmap}->{_ftp}, "tcp_rw", 1,
"FTP control traffic" );
my $p1 = $self->{_tcp_portmap}->{_tcp_or_udp};
if (defined ($p2 = $self->{_in_pat_port}) and
$self->{_port_str} eq "*" and
$self->accepting ()) {
$self->connect ($cl, $p1, "rw", $p2, "BEWARE! No firewalling");
} else {
$self->connect ($cl, $p1, "rw", $port_map->{_drop},
"rewrite or drop!");
}
$self->discard ($cl, $self->{_tcp_portmap}->{_def},
"non TCP/UDP");
print "\n";
}
sub ip_from_extern_classify {
my ($self, $port) = @_;
$self->{_ip_from_extern_port} = $port;
return $self->ext_lab ();
}
sub ext_lab {
my ($self) = @_;
return $self->labelstr () . "_ext";
}