-
Notifications
You must be signed in to change notification settings - Fork 0
/
crc32.c
184 lines (152 loc) · 5.16 KB
/
crc32.c
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
/*******************************************************************************
*
* crc32.c - CRC32 implementation
*
* Copyright (c) 2023 Basil Hussain
*
* Permission is hereby granted, free of charge, to any person obtaining a copy
* of this software and associated documentation files (the "Software"), to deal
* in the Software without restriction, including without limitation the rights
* to use, copy, modify, merge, publish, distribute, sublicense, and/or sell
* copies of the Software, and to permit persons to whom the Software is
* furnished to do so, subject to the following conditions:
*
* The above copyright notice and this permission notice shall be included in
* all copies or substantial portions of the Software.
*
* THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
* IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
* FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
* AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
* LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
* OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE
* SOFTWARE.
*
******************************************************************************/
#include <stddef.h>
#include <stdint.h>
#include "../crc.h"
#include "common.h"
// CRC32 (aka GZIP, PKZIP, PNG, ZMODEM)
// Polynomial: x^32 + x^26 + x^23 + x^22 + x^16 + x^12 + x^11 + x^10 + x^8 + x^7 + x^5 + x^4 + x^2 + x + 1 (0xEDB88320, reversed)
// Initial value: 0xFFFFFFFF
// XOR out: 0xFFFFFFFF
#ifdef ALGORITHM_LUT
static const uint32_t crc32_lut[16] = {
0x00000000, 0x1DB71064, 0x3B6E20C8, 0x26D930AC,
0x76DC4190, 0x6B6B51F4, 0x4DB26158, 0x5005713C,
0xEDB88320, 0xF00F9344, 0xD6D6A3E8, 0xCB61B38C,
0x9B64C2B0, 0x86D3D2D4, 0xA00AE278, 0xBDBDF21C
};
uint32_t crc32_update(uint32_t crc, uint8_t data) __naked __stack_args {
// Avoid compiler warnings for unreferenced args.
(void)crc;
(void)data;
// For return value/arg: 0xAABBCCDD
// x = 0xCCDD (xh = 0xCC, xl = 0xDD)
// y = 0xAABB (yh = 0xAA, yl = 0xBB)
__asm
; XOR the LSB of the CRC with data byte and store back to CRC.
ld a, (ASM_ARGS_SP_OFFSET+4, sp)
xor a, (ASM_ARGS_SP_OFFSET+3, sp)
ld (ASM_ARGS_SP_OFFSET+3, sp), a
.rept 2
; Take least-significant nibble of CRC and use as index into LUT.
; But, we want it as a byte offset into the LUT. Mask the low nibble
; and multiply by 4.
ld a, (ASM_ARGS_SP_OFFSET+3, sp)
and a, #0x0F
sll a
sll a
; LUT offset is in A, but we need it in X to perform the lookup.
clrw x
ld xl, a
; Shift the CRC value on the stack right by 4 bits.
; Oh, my kingdom for a barrel shifter!
.rept 4
srl (ASM_ARGS_SP_OFFSET+0, sp)
rrc (ASM_ARGS_SP_OFFSET+1, sp)
rrc (ASM_ARGS_SP_OFFSET+2, sp)
rrc (ASM_ARGS_SP_OFFSET+3, sp)
.endm
; For each byte of the CRC on stack, XOR it with the corresponding
; byte of the value in LUT (loaded from offset given in X), and
; store it back on the stack.
ld a, (_crc32_lut+0, x)
xor a, (ASM_ARGS_SP_OFFSET+0, sp)
ld (ASM_ARGS_SP_OFFSET+0, sp), a
ld a, (_crc32_lut+1, x)
xor a, (ASM_ARGS_SP_OFFSET+1, sp)
ld (ASM_ARGS_SP_OFFSET+1, sp), a
ld a, (_crc32_lut+2, x)
xor a, (ASM_ARGS_SP_OFFSET+2, sp)
ld (ASM_ARGS_SP_OFFSET+2, sp), a
ld a, (_crc32_lut+3, x)
xor a, (ASM_ARGS_SP_OFFSET+3, sp)
ld (ASM_ARGS_SP_OFFSET+3, sp), a
.endm
; Load CRC value from stack into X and Y regs for function return value.
ldw y, (ASM_ARGS_SP_OFFSET+0, sp)
ldw x, (ASM_ARGS_SP_OFFSET+2, sp)
ASM_RETURN
__endasm;
}
#else
uint32_t crc32_update(uint32_t crc, uint8_t data) __naked __stack_args {
// Avoid compiler warnings for unreferenced args.
(void)crc;
(void)data;
// For return value/arg: 0xAABBCCDD
// x = 0xCCDD (xh = 0xCC, xl = 0xDD)
// y = 0xAABB (yh = 0xAA, yl = 0xBB)
__asm
; XOR the LSB of the CRC with data byte, and put it back in the CRC.
ld a, (ASM_ARGS_SP_OFFSET+4, sp)
xor a, (ASM_ARGS_SP_OFFSET+3, sp)
ld (ASM_ARGS_SP_OFFSET+3, sp), a
; Load CRC variable from stack into X & Y regs for further work.
ldw x, (ASM_ARGS_SP_OFFSET+2, sp)
ldw y, (ASM_ARGS_SP_OFFSET+0, sp)
.macro crc32_update_shift_xor skip_lbl
; Shift CRC value right by one bit.
srlw y
rrcw x
; Jump if least-significant bit of CRC is now zero.
jrnc skip_lbl
; XOR the CRC value with the polynomial value.
rrwa x
xor a, #0x20
rrwa x
xor a, #0x83
rrwa x
rrwa y
xor a, #0xB8
rrwa y
xor a, #0xED
rrwa y
skip_lbl:
.endm
#ifdef ALGORITHM_BITWISE_UNROLLED
crc32_update_shift_xor 0001$
crc32_update_shift_xor 0002$
crc32_update_shift_xor 0003$
crc32_update_shift_xor 0004$
crc32_update_shift_xor 0005$
crc32_update_shift_xor 0006$
crc32_update_shift_xor 0007$
crc32_update_shift_xor 0008$
#else
; Initialise counter to loop 8 times, once for each bit of data byte.
ld a, #8
0001$:
crc32_update_shift_xor 0002$
; Decrement counter and loop around if it is not zero.
dec a
jrne 0001$
#endif
; The X and Y registers now contain updated CRC value, so leave them
; there as function return value.
ASM_RETURN
__endasm;
}
#endif