-
Notifications
You must be signed in to change notification settings - Fork 6.9k
/
THROTTLE_CONTROL_ROUTINES.agc
224 lines (198 loc) · 5.77 KB
/
THROTTLE_CONTROL_ROUTINES.agc
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
# Copyright: Public domain.
# Filename: THROTTLE_CONTROL_ROUTINES.agc
# Purpose: Part of the source code for Luminary 1A build 099.
# It is part of the source code for the Lunar Module's (LM)
# Apollo Guidance Computer (AGC), for Apollo 11.
# Assembler: yaYUL
# Contact: HARTMUTH GUTSCHE <hgutsche@xplornet.com>.
# Website: www.ibiblio.org/apollo.
# Pages: 793-797
# Mod history: 2009-05-20 HG Transcribed from page images.
#
# This source code has been transcribed or otherwise adapted from
# digitized images of a hardcopy from the MIT Museum. The digitization
# was performed by Paul Fjeld, and arranged for by Deborah Douglas of
# the Museum. Many thanks to both. The images (with suitable reduction
# in storage size and consequent reduction in image quality as well) are
# available online at www.ibiblio.org/apollo. If for some reason you
# find that the images are illegible, contact me at info@sandroid.org
# about getting access to the (much) higher-quality images which Paul
# actually created.
#
# Notations on the hardcopy document read, in part:
#
# Assemble revision 001 of AGC program LMY99 by NASA 2021112-061
# 16:27 JULY 14, 1969
# Page 793
BANK 31
SETLOC FTHROT
BANK
EBANK= PIF
COUNT* $$/THROT
# * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *
# HERE FC, DESIRED THRUST, AND FP, PRESENT THRUST, UNWEIGHTED, ARE COMPUTED.
THROTTLE CA ABDELV # COMPUTE PRESENT ACCELERATION IN UNITS OF
EXTEND # 2(-4) M/CS/CS, SAVING SERVICER TROUBLE
MP /AF/CNST
+3 EXTEND
QXCH RTNHOLD
AFDUMP TC MASSMULT
DXCH FP # FP = PRESENT THRUST
EXTEND
DCA /AFC/
TC MASSMULT
TS FC # FC = THRUST DESIRED BY GUIDANCE
DXCH FCODD # FCODD = WHAT IT IS GOING TO GET
# IF IT HAS BEEN LESS THAN 3 SECONDS SINCE THE LAST THROTTLING, AUGMENT FP USING THE FWEIGHT CALCULATED THEN.
CS TTHROT # THIS CODING ASSUMES A FLATOUT WITHIN
AD TIME1 # 80 SECONDS BEFORE FIRST THROTTLE CALL
MASK POSMAX
COM
AD 3SECS
EXTEND
BZMF WHERETO # BRANCH IF (TIME1-TTHROT +1) > 3 SECONDS
EXTEND
DCA FWEIGHT
DAS FP
# THIS LOGIC DETERMINES THE THROTTLING IN THE REGION 10% - 94%. THE MANUAL THROTTLE, NOMINALLY SET AT
# MINIMUM BY ASTRONAUT OR MISSION CONTROL PROGRAMS, PROVIDES THE LOWER BOUND. A STOP IN THE THROTTLE HARDWARE
# PROVIDES THE UPPER.
WHERETO CA EBANK5 # INITIALIZE L*WCR*T AND H*GHCR*T FROM
TS EBANK # PAD LOADED ERASABLES IN W-MATRIX
# Page 794
EBANK= LOWCRIT
EXTEND
DCA LOWCRIT
DXCH L*WCR*T
CA EBANK7
TS EBANK
EBANK= PIF
CS ZERO # INITIALIZE PIFPSET
TS PIFPSET
CS H*GHCR*T
AD FCOLD
EXTEND
BZMF LOWFCOLD # BRANCH IF FCOLD < OR = HIGHCRIT
CS L*WCR*T
AD FCODD
EXTEND
BZMF FCOMPSET # BRANCH IF FC < OR = LOWCRIT
CA FP # SEE NOTE 1
TCF FLATOUT1
FCOMPSET CS FMAXODD # SEE NOTE 2
AD FP
TCF FLATOUT2
LOWFCOLD CS H*GHCR*T
AD FCODD
EXTEND
BZMF DOPIF # BRANCH IF FC < OR = HIGHCRIT
CA FMAXPOS # NO: THROTTLE-UP
FLATOUT1 DXCH FCODD
CA FEXTRA
FLATOUT2 TS PIFPSET
# NOTE 1 FC IS SET EQUAL TO FP SO PIF WILL BE ZERO. THIS IS DESIRABLE
# AS THERE IS ACTUALLY NO THROTTLE CHANGE.
#
# NOTE 2 HERE, SINCE WE ARE ABOUT TO RETURN TO THE THROTTLEABLE REGION
# (BELOW 55%) THE QUANTITY -(FMAXODD - FP) IS COMPUTED AND PUT
# INTO PIFPSET TO COMPENSATE FOR THE DIFFERENCE BETWEEN THE
# NUMBER OF BITS CORRESPONDING TO FULL THROTTLE (FMAXODD) AND THE
# NUMBER CORRESPONDING TO ACTUAL THRUST (FP). THUS THE TOTAL
# THROTTLE COMMAND PIF = FC - FP - (FMAXODD - FP) = FC - FMAXODD.
DOPIF TC FASTCHNG
EXTEND
DCA FCODD
TS FCOLD
DXCH PIF
EXTEND
# Page 795
DCS FP
DAS PIF # PIF = FC - FP, NEVER EQUALS +0
DOIT CA PIF
AD PIFPSET # ADD IN PIFPSET, WITHOUT CHANGING PIF
TS PSEUDO55
TS THRUST
CAF BIT4
EXTEND
WOR CHAN14
CA TIME1
TS TTHROT
# SINCE /AF/ IS NOT AN INSTANTANEOUS ACCELERATION, BUT RATHER AN "AVERAGE" OF THE ACCELERATION LEVELS DURING
# THE PRECEEDING PIPA INTERVAL, AND SINCE FP IS COMPUTED DIRECTLY FROM /AF/, FP IN ORDER TO CORRESPOND TO THE
# ACTUAL THRUST LEVEL AT THE END OF THE INTERVAL MUST BE WEIGHTED BY
#
# PIF(PPROCESS + TL) PIF /PIF/
# FWEIGHT = ------------------ + -------------
# PGUID 2 PGUID FRATE
#
# WHERE PPROCESS IS THE TIME BETWEEN PIPA READING AND THE START OF THROTTLING, PGUID IS THE GUIDANCE PERIOD, AND
# FRATE IS THE THROTTLING RATE (32 UNITS PER CENTISECOND). PGUID IS EITHER 1 OR 2 SECONDS. THE "TL" IN THE
# FIRST TERM REPRESENTS THE ENGINE'S RESPONSE LAG. HERE FWEIGHT IS COMPUTED FOR USE NEXT PASS.
CA THISTPIP +1 # INITIALIZE FWEIGHT COMP AS IF FOR P66
TS BUF
CS MODREG # ARE WE IN FACT IN P66?
AD DEC66
EXTEND
BZF FWCOMP # YES
CA PIPTIME +1 # NO: INITIALIZE FOR TWO SECOND PERIOD
TS BUF
CAF 4SECS
TCF FWCOMP +1
FWCOMP CAF 2SECS
+1 TS Q
EXTEND
MP BIT6
LXCH BUF +1
CS BUF # TIME OF LAST PIPA READING.
AD TIME1
AD THROTLAG # COMPENSATE FOR ENGINE RESPONSE LAG
MASK LOW8 # MAKE SURE SMALL AND POSITIVE
ZL
EXTEND
# Page 796
DV Q
EXTEND
MP PIF
DOUBLE
DXCH FWEIGHT
CCS PIF
AD ONE
TCF +2
AD ONE
EXTEND
MP PIF
EXTEND
DV BUF +1
ZL
DAS FWEIGHT
THDUMP TC RTNHOLD
# FLATOUT THROTTLES UP THE DESCENT ENGINE, AND IS CALLED AS A BASIC SUBROUTINE.
FLATOUT CAF BIT13 # 4096 PULSES
WHATOUT TS PIFPSET # USE PIFPSET SO FWEIGHT WILL BE ZERO
CS ZERO
TS FCOLD
TS PIF
EXTEND
QXCH RTNHOLD
TCF DOIT
# MASSMULT SCALES ACCELERATION, ARRIVING IN A AND L IN UNITS OF 2(-4) M/CS/CS, TO FORCE IN PULSE UNITS.
MASSMULT EXTEND
QXCH BUF
DXCH MPAC
TC DMP
ADRES MASS
TC DMP # LEAVES PROPERLY SCALED FORCE IN MPAC
ADRES SCALEFAC
TC TPAGREE
CA MPAC
EXTEND
BZF +3
CAF POSMAX
TC BUF
DXCH MPAC +1
TC BUF
# Page 797
# CONSTANTS:-
FEXTRA = BIT13 # FEXT +5.13309020E+ 4
/AF/CNST DEC .13107
# * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * *