-
Notifications
You must be signed in to change notification settings - Fork 38
/
json_formatter.cr
170 lines (157 loc) · 4.01 KB
/
json_formatter.cr
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
require "json"
module Ameba::Formatter
# A formatter that produces the result in a json format.
#
# Example:
#
# ```
# {
# "metadata": {
# "ameba_version": "x.x.x",
# "crystal_version": "x.x.x",
# },
# "sources": [
# {
# "issues": [
# {
# "location": {
# "column": 7,
# "line": 17,
# },
# "end_location": {
# "column": 20,
# "line": 17,
# },
# "message": "Useless assignment to variable `a`",
# "rule_name": "UselessAssign",
# "severity": "Convention",
# },
# {
# "location": {
# "column": 7,
# "line": 18,
# },
# "end_location": {
# "column": 8,
# "line": 18,
# },
# "message": "Useless assignment to variable `a`",
# "rule_name": "UselessAssign",
# },
# {
# "location": {
# "column": 7,
# "line": 19,
# },
# "end_location": {
# "column": 9,
# "line": 19,
# },
# "message": "Useless assignment to variable `a`",
# "rule_name": "UselessAssign",
# "severity": "Convention",
# },
# ],
# "path": "src/ameba/formatter/json_formatter.cr",
# },
# ],
# "summary": {
# "issues_count": 3,
# "target_sources_count": 1,
# },
# }
# ```
class JSONFormatter < BaseFormatter
def initialize(@output = STDOUT)
@result = AsJSON::Result.new
end
def started(sources)
@result.summary.target_sources_count = sources.size
end
def source_finished(source : Source)
json_source = AsJSON::Source.new source.path
source.issues.each do |issue|
next if issue.disabled?
next if issue.correctable? && config[:autocorrect]?
json_source.issues << AsJSON::Issue.new(
issue.rule.name,
issue.rule.severity.to_s,
issue.location,
issue.end_location,
issue.message
)
@result.summary.issues_count += 1
end
@result.sources << json_source
end
def finished(sources)
@result.to_json @output
end
end
private module AsJSON
record Result,
sources = [] of Source,
metadata = Metadata.new,
summary = Summary.new do
def to_json(json)
{
sources: sources,
metadata: metadata,
summary: summary,
}.to_json(json)
end
end
record Source,
path : String,
issues = [] of Issue do
def to_json(json)
{
path: path,
issues: issues,
}.to_json(json)
end
end
record Issue,
rule_name : String,
severity : String,
location : Crystal::Location?,
end_location : Crystal::Location?,
message : String do
def to_json(json)
{
rule_name: rule_name,
severity: severity,
message: message,
location: {
line: location.try &.line_number,
column: location.try &.column_number,
},
end_location: {
line: end_location.try &.line_number,
column: end_location.try &.column_number,
},
}.to_json(json)
end
end
record Metadata,
ameba_version : String = Ameba::VERSION,
crystal_version : String = Crystal::VERSION do
def to_json(json)
{
ameba_version: ameba_version,
crystal_version: crystal_version,
}.to_json(json)
end
end
class Summary
property target_sources_count = 0
property issues_count = 0
def to_json(json)
{
target_sources_count: target_sources_count,
issues_count: issues_count,
}.to_json(json)
end
end
end
end