-
Notifications
You must be signed in to change notification settings - Fork 1
/
AsifAdditions.pas
319 lines (277 loc) · 9.58 KB
/
AsifAdditions.pas
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
unit AsifAdditions;
interface
uses
Asif, Windows, Graphics, Types, Classes, SysUtils, StrUtils, GR32, YShared;
type
TFilterType = (ft25, ft25STDCALL, ftImport, ftError);
PAvisynthFilter = ^TAvisynthFilter;
TAvisynthFilter = record
FunctionName: string;
FileName: string;
FilterType: TFilterType;
end;
TAvisynthFilterDynArray = array of TAvisynthFilter;
procedure InitializeFilterlist(Filename: string = '');
procedure FieldAssemble(Top, Bottom: Integer; Clip: IAsifClip; OutImage: TBitmap32);
procedure FullFrame(AFrame: Integer; Clip: IAsifClip; OutImage: TBitmap32);
procedure LoadPlugins(PluginText: string; PluginPath: string; Env: IAsifScriptEnvironment; Level: Integer = 1);
function GetRequiredPlugins(AllPlugins: Boolean; PluginText: string; PluginPath: string; Env: IAsifScriptEnvironment; Level: Integer = 1; ExistingPlugins: TAvisynthFilterDynArray = nil): TAvisynthFilterDynArray;
function PluginListToScript(Plugins: TAvisynthFilterDynArray; PluginPath: string): string;
implementation
var
FilterList: TAvisynthFilterDynArray;
function PluginListToScript(Plugins: TAvisynthFilterDynArray; PluginPath: string): string;
var
Counter: Integer;
begin
Result := '';
//multiple passess to get the right order since the list is unsorted
for Counter := 0 to Length(Plugins) - 1 do
with Plugins[Counter] do
case FilterType of
ft25: Result := Format('%sLoadPlugin("%s%s")'#13#10, [Result, PluginPath, FileName]);
ft25STDCALL: Result := Format('%sload_stdcall_plugin("%s%s")'#13#10, [Result, PluginPath, FileName]);
end;
for Counter := 0 to Length(Plugins) - 1 do
with Plugins[Counter] do
if FilterType = ftImport then
Result := Format('%sImport("%s%s")'#13#10, [Result, PluginPath, FileName]);
end;
function StrToFilterType(const S: string): TFilterType;
begin
if SameText(S, '25') then
Result := ft25
else if SameText(S, '25STDCALL') then
Result := ft25STDCALL
else if SameText(S, 'Import') then
Result := ftImport
else
Result := ftError;
end;
procedure InitializeFilterlist(Filename: string = '');
var
TempList: TStringList;
Counter: Integer;
Line: string;
begin
SetLength(FilterList, 0);
if (Filename <> '') and FileExists(Filename) then
begin
TempList := TStringList.Create;
try
TempList.LoadFromFile(Filename);
for Counter := 0 to TempList.Count - 1 do
begin
Line := TempList[Counter];
if (Line <> '') and (Line[1] <> '#') then
begin
SetLength(FilterList, Length(FilterList) + 1);
with FilterList[High(FilterList)] do
begin
FilterType := StrToFilterType(GetToken(Line, 0));
FileName := GetToken(Line, 1);
FunctionName := GetToken(Line, 2);
if (FilterType = ftError) or (FileName = '') or (FunctionName = '') then
raise EAsifException.CreateFmt('Incorrect filter declaration on line %d'#13#10'%s', [Counter + 1, Line]);
end;
end;
end;
finally
TempList.Free;
end;
end;
end;
function GetRequiredPlugins(AllPlugins: Boolean; PluginText: string; PluginPath: string; Env: IAsifScriptEnvironment; Level: Integer; ExistingPlugins: TAvisynthFilterDynArray): TAvisynthFilterDynArray;
function PluginAlreadyAdded(CurrentFilters: TAvisynthFilterDynArray; Plugin: TAvisynthFilter): Boolean;
var
Counter: Integer;
begin
Result := False;
for Counter := 0 to Length(CurrentFilters) - 1 do
with CurrentFilters[Counter] do
if (Plugin.FilterType = FilterType) and (Plugin.FileName = FileName) then
begin
Result := True;
Break;
end;
end;
var
Counter, MergeCounter: Integer;
IncludeContents: TStringList;
TempPlugins: TAvisynthFilterDynArray;
Tokens: TStringList;
Offset: Integer;
Token: string;
PreviousToken: string;
begin
Result := nil;
Tokens := TStringList.Create;
Tokens.CaseSensitive := False;
Offset := 1;
PreviousToken := '';
try
while True do
begin
Token := GetNextToken(PluginText, Offset, [#0..#255] - ['1'..'9', '0', 'a'..'z', 'A'..'Z', '_']);
if Token = '' then
Break;
if (Offset <= Length(PluginText)) and (PluginText[Offset] = '(') and (PreviousToken <> 'function') then
Tokens.Append(Token);
PreviousToken := Token;
end;
for Counter := 0 to Length(FilterList) - 1 do
with FilterList[Counter] do
begin
if (AnsiSameText(PluginText, FunctionName) or (Tokens.IndexOf(FunctionName) <> -1)) and ((not Env.FunctionExists(FunctionName)) or AllPlugins) and not PluginAlreadyAdded(Result, FilterList[Counter]) then
begin
SetLength(Result, Length(Result) + 1);
Result[High(Result)] := FilterList[Counter];
if FilterType = ftImport then
if Level = 1 then
begin
if not FileExists(PluginPath + FileName) then
raise EAsifException.Create('Couldn''t locate "' + FileName + '"');
IncludeContents := TStringList.Create;
try
IncludeContents.LoadFromFile(PluginPath + FileName);
TempPlugins := GetRequiredPlugins(AllPlugins, IncludeContents.Text, PluginPath, Env, Level + 1);
for MergeCounter := 0 to Length(TempPlugins) - 1 do
if not PluginAlreadyAdded(Result, TempPlugins[MergeCounter]) then
begin
SetLength(Result, Length(Result) + 1);
Result[High(Result)] := TempPlugins[MergeCounter];
end;
TempPlugins := nil;
finally
IncludeContents.Free;
end;
end;
end;
end;
finally
Tokens.Free;
end;
end;
procedure LoadPlugins(PluginText: string; PluginPath: string; Env: IAsifScriptEnvironment; Level: Integer);
var
Plugins: TAvisynthFilterDynArray;
Counter: Integer;
CurrentPath: string;
begin
CurrentPath := GetCurrentDir;
try
Plugins := GetRequiredPlugins(False, PluginText, PluginPath, Env);
SetCurrentDir(PluginPath);
for Counter := 0 to Length(Plugins) - 1 do
with Plugins[Counter] do
begin
if FileExists(PluginPath + FileName) then
begin
if FilterType = ft25STDCALL then
begin
try
Env.CharArg(PChar(PluginPath + FileName));
Env.Invoke('load_stdcall_plugin');
except on EAsifException do
raise EAsifException.Create('Couldn''t load the plugin "' + FileName + '"');
end;
end
else if FilterType = ft25 then
begin
try
Env.CharArg(PChar(PluginPath + FileName));
Env.Invoke('LoadPlugin');
except on EAsifException do
raise EAsifException.Create('Couldn''t load the plugin "' + FileName + '"');
end;
end;
end
else
raise EAsifException.Create('Couldn''t locate "' + FileName + '"');
end;
for Counter := 0 to Length(Plugins) - 1 do
with Plugins[Counter] do
begin
if FileExists(PluginPath + FileName) then
begin
if FilterType = ftImport then
begin
try
Env.CharArg(PChar(PluginPath + FileName));
Env.Invoke('Import');
except on EAsifException do
raise EAsifException.Create('Couldn''t import the script "' + FileName + '"');
end;
end;
end
else
raise EAsifException.Create('Couldn''t locate "' + FileName + '"');
end;
finally
SetCurrentDir(CurrentPath);
end;
end;
procedure FieldAssemble(Top, Bottom: Integer; Clip: IAsifClip; OutImage: TBitmap32);
var
VI: VideoInfo;
Counter, DSTRow: integer;
SRCP: PByte;
Frame: IAsifVideoFrame;
SrcPitch: Integer;
RowSize: Integer;
begin
if Top = Bottom then
FullFrame(Top, Clip, OutImage)
else
begin
VI := Clip.GetVideoInfo;
OutImage.Height := VI.Height;
OutImage.Width := VI.Width;
Frame := Clip.GetFrame(Top);
SRCP := Frame.GetReadPtr(0);
RowSize := Frame.GetRowSize(0);
SrcPitch := Frame.GetPitch(0);
DSTRow := VI.Height - 1;
for Counter := VI.Height div 2 - 1 downto 0 do
begin
CopyMemory(OutImage.ScanLine[DSTRow], SRCP, RowSize);
Inc(SRCP, 2 * SrcPitch);
Dec(DSTRow, 2)
end;
Frame := Clip.GetFrame(Bottom);
SRCP := Frame.GetReadPtr(0);
RowSize := Frame.GetRowSize(0);
SrcPitch := Frame.GetPitch(0);
Inc(SRCP, SrcPitch);
DSTRow := VI.Height - 2;
for Counter := VI.Height div 2 - 1 downto 0 do
begin
CopyMemory(OutImage.ScanLine[DSTRow], SRCP, RowSize);
Inc(SRCP, 2 * SrcPitch);
Dec(DSTRow, 2)
end;
end;
end;
procedure FullFrame(AFrame: Integer; Clip: IAsifClip; OutImage: TBitmap32);
var
VI: VideoInfo;
Counter: Integer;
SRCP: PByte;
Frame: IAsifVideoFrame;
SrcPitch: Integer;
RowSize: Integer;
begin
VI := Clip.GetVideoInfo;
OutImage.Height := VI.Height;
OutImage.Width := VI.Width;
Frame := Clip.GetFrame(AFrame);
SRCP := Frame.GetReadPtr(0);
RowSize := Frame.GetRowSize(0);
SrcPitch := Frame.GetPitch(0);
for Counter := VI.Height - 1 downto 0 do
begin
CopyMemory(OutImage.ScanLine[Counter], SRCP, RowSize);
Inc(SRCP, SrcPitch);
end;
end;
end.