-
Notifications
You must be signed in to change notification settings - Fork 0
/
FormMacroHelper.4dm
1084 lines (852 loc) · 23.6 KB
/
FormMacroHelper.4dm
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
// structure de l'object editor
// form : object -> Whole form - All modification in this object are ignored.
// name : form name
// formProperties : object ->The property of the current form.
// file : .4dform file object
// table : name
// currentPage.objects : object ->The current page
// currentSelection : collection -> Collection of the selected object name
// target : the name of the clicked object
Class constructor
var $1 : Object
This:C1470.editor:=$1.editor
Function strcmp
var $1; $2 : Text
var $0 : Boolean
$0:=False:C215
If (Length:C16($1)=Length:C16($2))
$0:=Position:C15($1; $2; *)=1
End if
Function EncodeReservedFileCharacters
var $1; $0 : Text
var $c; $i; $reserved_count : Integer
var $reserved; $hexa : Text
$reserved:="1111111111"*3
$reserved:=$reserved+"1100100100"
$reserved:=$reserved+"0010000100"
$reserved:=$reserved+"0000000010"
$reserved:=$reserved+"1011000000"
$reserved:=$reserved+("0000000000"*2)
$reserved:=$reserved+"0010000000"
$reserved:=$reserved+("0000000000"*2)
$reserved:=$reserved+"000010000"
$hexa:="0123456789ABCDEF"
$reserved_count:=Length:C16($reserved)
For ($i; 1; Length:C16($1))
$c:=Character code:C91($1[[$i]])
If ($c<$reserved_count) & ($reserved[[$c+1]]#"0")
$0:=$0+"%"
$0:=$0+$hexa[[($c\16)+1]]
$0:=$0+$hexa[[($c%16)+1]]
Else
$0:=$0+Char:C90($c)
End if
End for
Function DecodeReservedFileCharacters
var $1; $0 : Text
var $c; $v; $ii; $i; $len : Integer
$len:=Length:C16($1)
For ($i; 1; $len)
If ($1[[$i]]="%")
If (($i+2)<=$len)
$v:=0
For ($ii; 1; 2)
$c:=Character code:C91($1[[$i+$ii]])
Case of
: (($c>=Character code:C91("0")) & ($c<Character code:C91("9")))
$v:=$v*16
$v:=$v+($c-Character code:C91("0"))
: (($c>=Character code:C91("A")) & ($c<Character code:C91("F")))
$v:=$v*16
$v:=$v+($c-Character code:C91("A"))+10
: (($c>=Character code:C91("a")) & ($c<Character code:C91("f")))
$v:=$v*16
$v:=$v+($c-Character code:C91("a"))+10
End case
End for
$0:=$0+Char:C90($v)
$i:=$i+2
Else
$0:=$0+$1[[$i]]
End if
Else
$0:=$0+$1[[$i]]
End if
End for
Function _BuildObjectGroups
var $0 : Object
var $1 : Integer
var $in_PageNumber : Integer
$in_PageNumber:=$1
var $pageGroup; $page; $allGroups : Object
var $objects : Collection
var $groupName; $objName; $objectType : Text
var $done : Boolean
var $foundInPage : Integer
$done:=False:C215
$allGroups:=Null:C1517
$pageGroup:=Null:C1517
$page:=This:C1470._GetPage($in_PageNumber)
If ($page#Null:C1517)
If (This:C1470.editor.form.editor#Null:C1517)
$allGroups:=This:C1470.editor.form.editor.groups
End if
If ($allGroups#Null:C1517)
$pageGroup:=New object:C1471
For each ($groupName; $allGroups)
$objects:=$allGroups[$groupName]
If ($objects.length>0)
$done:=False:C215
For each ($objName; $objects) Until ($done=True:C214)
If ($objName#"")
If (This:C1470.FormObjectExist($objName; True:C214; ->$foundInPage))
If ($foundInPage=$in_PageNumber)
OB SET:C1220($pageGroup; $groupName; $objects.copy())
End if
$done:=True:C214
End if
End if
End for each
End if
End for each
End if
End if
If ($pageGroup#Null:C1517)
If (OB Is empty:C1297($pageGroup))
CLEAR VARIABLE:C89($pageGroup)
End if
End if
$0:=$pageGroup
Function _GetPage
var $1 : Integer
var $0 : Object
$0:=Null:C1517
If (($1>=0) & ($1<=This:C1470.GetPageCount()))
$0:=This:C1470.editor.form.pages[$1]
Else
If ($1=-1)
$0:=This:C1470.editor.currentPage
End if
End if
Function _GetObjectInPage
var $0; $1 : Object
var $2 : Text
var $3 : Pointer
var $in_page : Object
var $in_inName : Text
var $out_objecttype : Pointer
$in_page:=$1
$in_inName:=$2
$out_objecttype:=$3
var $found : Boolean
var $objectName; $objectType : Text
var $object; $col : Object
$out_objecttype->:=""
If (($in_page#Null:C1517) & ($in_inName#""))
If ($in_page.objects#Null:C1517)
For each ($objectName; $in_page.objects) While ($found=False:C215)
$object:=$in_page.objects[$objectName]
$objectType:=$object.type
//If (This.strcmp($objectName;$in_inName))
If ($objectName=$in_inName)
$found:=True:C214
$0:=$object
$out_objecttype->:=$objectType
Else
If (This:C1470.strcmp($objectType; "listbox"))
For each ($col; $object.columns) While ($found=False:C215)
If ($col.name=$in_inName)
//If (This.strcmp($col.name;$in_inName))
$found:=True:C214
$0:=$col
$out_objecttype->:="columns"
Else
If ($col.header.name=$in_inName)
//If (This.strcmp($col.header.name;$in_inName))
$found:=True:C214
$0:=$col.header
$out_objecttype->:="header"
Else
If ($col.footer.name=$in_inName)
//If (This.strcmp($col.footer.name;$in_inName))
$found:=True:C214
$0:=$col.footer
$out_objecttype->:="footer"
End if
End if
End if
End for each
End if
End if
End for each
End if
End if
Function _GetObjectNameInPage
var $0 : Collection
var $1 : Object
var $in_page : Object
$in_page:=$1
var $found : Boolean
var $objectName; $objectType : Text
var $object; $col : Object
$0:=New collection:C1472
If (($in_page#Null:C1517))
If ($in_page.objects#Null:C1517)
For each ($objectName; $in_page.objects)
$object:=$in_page.objects[$objectName]
$0.push($objectName)
If (This:C1470.strcmp($object.type; "listbox"))
// not a good practice, but
// sub object can have empty or not defined name. In this case , unique name will be generated when form will be loaded
For each ($col; $object.columns)
If ($col.name#"")
$0.push($col.name)
End if
If (OB Is defined:C1231($col; "header"))
If ($col.header.name#"")
$0.push($col.header.name)
End if
End if
If (OB Is defined:C1231($col; "footer"))
If ($col.footer.name#"")
$0.push($col.footer.name)
End if
End if
End for each
End if
End for each
End if
End if
Function GetObjectDefaultValues
var $0 : Object
var $1 : Text
var $in_objecttype : Text
$in_objecttype:=$1
var $DefaultJsonFormPath; $txt : Text
If (This:C1470.DefaultValues=Null:C1517)
Case of
: (Is Windows:C1573)
$DefaultJsonFormPath:=(Path to object:C1547(Application file:C491; Path is system:K24:25).parentFolder)+"Resources"+Folder separator:K24:12+"DefaultJsonForm.json"
: (Is macOS:C1572)
$DefaultJsonFormPath:=Application file:C491+Folder separator:K24:12+"Contents"+Folder separator:K24:12+"Resources"+Folder separator:K24:12+"DefaultJSONForm.json"
End case
If ($DefaultJsonFormPath#"")
$txt:=File:C1566($DefaultJsonFormPath; fk platform path:K87:2).getText()
This:C1470.DefaultValues:=JSON Parse:C1218($txt; Is object:K8:27)
End if
End if
If (This:C1470.DefaultValues#Null:C1517)
If ($in_objecttype#"")
$0:=This:C1470.DefaultValues[$in_objecttype]
Else
$0:=This:C1470.DefaultValues
End if
End if
Function GetFormName
var $0 : Text
$0:=This:C1470.editor.name
Function GetPageCount
var $0 : Integer
$0:=This:C1470.editor.form.pages.length
Function GetCurrentPageNumber
var $0 : Integer
$0:=This:C1470.editor.currentPageNumber
Function GetObjectMethodFolder
var $0 : Object
$0:=This:C1470.editor.file.parent.folder("ObjectMethods")
Function GetFormFolder
var $0 : Object
$0:=This:C1470.editor.file.parent
Function GetSelection
var $0 : Collection
If (This:C1470.editor.currentSelection=Null:C1517)
This:C1470.editor.currentSelection:=New collection:C1472
End if
$0:=This:C1470.editor.currentSelection
Function GetSelectedObjectCount
var $0 : Integer
$0:=This:C1470.GetSelection().length
Function DeselectAll
var $0 : Boolean
This:C1470.GetSelection().clear()
Function SelectAll
var $0 : Boolean
var $col : Collection
var $objects : Object
var $property : Text
$col:=This:C1470.GetSelection()
$objects:=This:C1470.editor.currentPage.objects
For each ($property; $objects)
$col.push($property)
End for each
Function SelectObject
var $0 : Boolean
var $1 : Text
var $col : Collection
$col:=This:C1470.GetSelection()
If ($1#"")
If ($col.indexOf($1)=-1)
$col.push($1)
End if
End if
Function DeselectObject
var $0 : Boolean
var $1 : Text
var $col : Collection
var $ind : Integer
$col:=This:C1470.GetSelection()
If ($1#"")
$ind:=$col.indexOf($1)
If ($ind#-1)
$col.remove($ind)
End if
End if
Function IsSelected
var $0 : Boolean
var $1 : Text
$0:=False:C215
If ($1#"")
$0:=(This:C1470.GetSelection().indexOf($1)#-1)
End if
Function GetFormObject
var $0 : Object
var $1 : Text
var $2 : Integer
var $3 : Pointer
var $in_objectName : Text
var $in_pageNumber : Integer
var $out_objectType : Pointer
$in_objectName:=$1
$in_pageNumber:=$2
$out_objectType:=$3
var $page : Object
var $pagelist : Collection
var $ind : Integer
// page number
// >=0 look in editor.form[page number] The returned object is readonly
// -1 look in editor.currentPage The returned object is readonly
// -2 look in editor.currentPage for current page , and editor.form for other.returned object can be r/o or r/w
// -3 look in editor.form The returned object is readonly
$out_objectType->:=""
If ($in_objectName#"")
Case of
: ($in_pageNumber=-1)
$0:=This:C1470._GetObjectInPage(This:C1470.editor.currentPage; $in_objectName; $out_objectType)
: ($in_pageNumber=-2)
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
$ind:=0
For each ($page; $pagelist) While ($0=Null:C1517)
If ($ind=This:C1470.GetCurrentPageNumber())
$page:=This:C1470.editor.currentPage
End if
If ($page#Null:C1517)
$0:=This:C1470._GetObjectInPage($page; $in_objectName; $out_objectType)
End if
$ind:=$ind+1
End for each
End if
: ($in_pageNumber=-3)
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
$ind:=0
For each ($page; $pagelist) While ($0=Null:C1517)
$0:=This:C1470._GetObjectInPage($page; $in_objectName; $out_objectType)
End for each
End if
Else
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
If ($in_pageNumber<$pagelist.length)
$0:=This:C1470._GetObjectInPage($pagelist[$in_pageNumber]; $in_objectName; $out_objectType)
End if
End if
End case
End if
Function GetFormObjectNames
var $0 : Collection
var $1 : Integer
var $in_pageNumber : Integer
$in_pageNumber:=$1
var $page : Object
var $pagelist; $col : Collection
var $ind; $curpagenumber : Integer
// page number
// >=0 look in editor.form[page number]
// -1 look in editor.currentPage
// -2 look in editor.currentPage for current page , and editor.form for other.
// -3 look in editor.form
$0:=New collection:C1472
Case of
: ($in_pageNumber=-1)
$0:=$0.concat(This:C1470._GetObjectNameInPage(This:C1470.editor.currentPage))
: ($in_pageNumber=-2)
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
$ind:=0
$curpagenumber:=This:C1470.GetCurrentPageNumber()
For each ($page; $pagelist)
If ($ind=$curpagenumber)
$page:=This:C1470.editor.currentPage
End if
If ($page#Null:C1517)
$0:=$0.concat(This:C1470._GetObjectNameInPage($page))
End if
$ind:=$ind+1
End for each
End if
: ($in_pageNumber=-3)
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
$ind:=0
For each ($page; $pagelist) While ($0=Null:C1517)
$0:=$0.concat(This:C1470._GetObjectNameInPage($page))
End for each
End if
Else
$pagelist:=This:C1470.editor.form.pages
If ($pagelist#Null:C1517)
If ($in_pageNumber<$pagelist.length)
$0:=$0.concat(This:C1470._GetObjectNameInPage($pagelist))
End if
End if
End case
Function FormObjectExist
var $0; $2 : Boolean
var $1 : Text
var $3 : Pointer
var $in_inName : Text
var $in_useCurrentPage : Boolean
var $out_pageNumber : Pointer
var $pageNumber : Integer
$in_inName:=$1
$in_useCurrentPage:=$2
If (Count parameters:C259=3)
$out_pageNumber:=$3
End if
var $pagelist : Collection
var $ind : Integer
var $page; $object : Object
var $objectType : Text
$0:=False:C215
If ($in_inName#"")
If (This:C1470.editor.form.pages#Null:C1517)
$pagelist:=This:C1470.editor.form.pages
$ind:=0
For each ($page; $pagelist) While ($0=False:C215)
If (($in_useCurrentPage=True:C214) & ($ind=This:C1470.GetCurrentPageNumber()))
$page:=This:C1470.editor.currentPage
$ind:=-1
Else
End if
If ($page#Null:C1517)
$object:=This:C1470._GetObjectInPage($page; $in_inName; ->$objectType)
End if
$0:=($object#Null:C1517)
If (Not:C34($0))
$ind:=$ind+1
End if
End for each
End if
End if
If (Not:C34(Is nil pointer:C315($out_pageNumber)))
$out_pageNumber->:=$ind
End if
Function MakeUniqueObjectName
var $0; $1 : Text
var $2 : Collection
var $3 : Boolean
var $in_wantedName : Text
var $in_exclusions : Collection
var $in_withFreeMethodFile : Boolean
$in_wantedName:=$1
$in_exclusions:=$2
$in_withFreeMethodFile:=$3
$0:=""
var $tmpName; $name; $tmpScriptName; $methodfolderpath : Text
var $names; $groups : Collection
var $found : Boolean
var $counter : Integer
// important
// this code don't use strict string compare (This.strcmp)
// because 4D object name is not case sensitive
If ($in_wantedName#"")
$names:=This:C1470.GetFormObjectNames(-2)
$groups:=This:C1470.GetAllGroupNames()
If ($names.length>0)
$counter:=0
$tmpName:=$in_wantedName
If ($in_withFreeMethodFile)
$methodfolderpath:=This:C1470.GetObjectMethodFolder().platformPath
End if
Repeat
$found:=False:C215
For each ($name; $names) While ($found=False:C215)
$found:=($tmpName=$name)
End for each
// groups
If (($groups.length>0) & ($found=False:C215))
For each ($name; $groups) While ($found=False:C215)
$found:=($tmpName=$name)
End for each
End if
// look in exclusion list
If (($in_exclusions#Null:C1517) & ($found=False:C215))
For each ($name; $in_exclusions) While ($found=False:C215)
$found:=($tmpName=$name)
End for each
End if
// test method file name
If (($in_withFreeMethodFile) & ($found=False:C215))
$tmpScriptName:=This:C1470.EncodeReservedFileCharacters($tmpName)
$found:=(Test path name:C476($methodfolderpath+$tmpScriptName+".4dm")=Is a document:K24:1)
End if
If ($found)
$counter:=$counter+1
$tmpName:=$in_wantedName+String:C10($counter)
Else
$0:=$tmpName
End if
Until ($0#"")
Else
$0:=$in_wantedName
End if
End if
Function InsertFormObjectAfter
var $2 : Object
var $1; $3 : Text
var $0 : Boolean
var $in_newObjectName; $in_afterObjectName : Text
var $in_newObject : Object
$in_newObjectName:=$1
$in_afterObjectName:=$3
$in_newObject:=$2
var $objects; $newObjects : Object
var $property : Text
$0:=False:C215
$objects:=This:C1470.editor.currentPage.objects
If ($in_newObjectName#"")
If (Not:C34(OB Is defined:C1231($objects; $in_newObjectName)))
If ($in_afterObjectName="")
$objects[$in_newObjectName]:=$in_newObject
$0:=True:C214
Else
$newObjects:=New object:C1471
For each ($property; $objects)
$newObjects[$property]:=$objects[$property]
If (This:C1470.strcmp($property; $in_afterObjectName))
$newObjects[$in_newObjectName]:=$in_newObject
End if
End for each
This:C1470.editor.currentPage.objects:=$newObjects
$0:=True:C214
End if
End if
End if
Function InsertFormObjectBefore
var $2 : Object
var $1; $3 : Text
var $0 : Boolean
var $in_newObjectName; $in_beforeObjectName : Text
var $in_newObject : Object
$in_newObjectName:=$1
$in_beforeObjectName:=$3
$in_newObject:=$2
var $objects; $newObjects : Object
var $newObjectName; $property : Text
$0:=False:C215
$objects:=This:C1470.editor.currentPage.objects
If ($newObjectName#"")
If (Not:C34(OB Is defined:C1231($objects; $in_beforeObjectName)))
$newObjects:=New object:C1471
If ($in_beforeObjectName="")
$newObjects[$in_newObjectName]:=$in_newObject
End if
For each ($property; $objects)
If ($in_beforeObjectName#"")
If (This:C1470.strcmp($property; $in_beforeObjectName))
$newObjects[$in_newObjectName]:=$in_newObject
End if
End if
$newObjects[$property]:=$objects[$property]
End for each
This:C1470.editor.currentPage.objects:=$newObjects
$0:=True:C214
End if
End if
Function RenameObject
var $1; $2 : Text
var $0 : Boolean
var $in_OldName; $in_NewName : Text
$in_OldName:=$1
$in_NewName:=$2
var $objects; $newObjects : Object
var $property : Text
var $ind : Integer
$0:=False:C215
If (This:C1470.FormObjectExist($in_OldName; True:C214))
If (Not:C34(This:C1470.FormObjectExist($in_NewName; True:C214)))
$objects:=This:C1470.editor.currentPage.objects
$newObjects:=New object:C1471
For each ($property; $objects)
//If (This.strcmp($property;$in_OldName))
If ($property=$in_OldName)
$newObjects[$in_NewName]:=$objects[$property]
Else
$newObjects[$property]:=$objects[$property]
End if
End for each
This:C1470.editor.currentPage.objects:=$newObjects
If (This:C1470.IsSelected($in_OldName))
This:C1470.DeselectObject($in_OldName)
This:C1470.SelectObject($in_NewName)
End if
$ind:=This:C1470.FindInEntryOrder($in_OldName)
If ($ind#-1)
This:C1470.GetEntryOrder()[$ind]:=$in_NewName
End if
$0:=True:C214
End if
End if
Function ObjectGetX
var $1 : Object
var $0 : Integer
$0:=$1.left
Function ObjectGetY
var $1 : Object
var $0 : Integer
$0:=$1.top
Function ObjectGetRight
var $1 : Object
var $0 : Integer
$0:=$1.left+This:C1470.ObjectGetWidth($1)
Function ObjectGetBottom
var $1 : Object
var $0 : Integer
$0:=$1.top+This:C1470.ObjectGetHeight($1)
Function ObjectGetWidth
var $1 : Object
var $0 : Integer
If (OB Is defined:C1231($1; "right"))
$0:=$1.right-$1.left
Else
$0:=$1.width
End if
Function ObjectSetWidth
var $1 : Object
var $2 : Integer
var $w; $r : Boolean
$r:=OB Is defined:C1231($1; "right")
$w:=OB Is defined:C1231($1; "width")
If (($r=True:C214) | (($r=False:C215) & ($w=False:C215)))
$1.right:=$1.left+$2
End if
If ($w)
$1.width:=$2
End if
Function ObjectGetHeight
var $1 : Object
var $0 : Integer
If (OB Is defined:C1231($1; "bottom"))
$0:=$1.bottom-$1.top
Else
$0:=$1.height
End if
Function ObjectSetHeight
var $1 : Object
var $2 : Integer
var $b; $h : Boolean
$b:=OB Is defined:C1231($1; "bottom")
$h:=OB Is defined:C1231($1; "height")
If (($b=True:C214) | (($b=False:C215) & ($h=False:C215)))
$1.bottom:=$1.top+$2
End if
If ($h)
$1.height:=$2
End if
Function ObjectSetX
var $1 : Object
var $2 : Integer
var $r; $w : Boolean
$r:=OB Is defined:C1231($1; "right")
$w:=OB Is defined:C1231($1; "width")
If ($w | $r)
If ($r)
$1.right:=$2+($1.right-$1.left)
$1.left:=$2
End if
If ($w)
$1.left:=$2
End if
Else
ASSERT:C1129(False:C215)
End if
Function ObjectSetY
var $1 : Object
var $2 : Integer
var $b; $h : Boolean
$b:=OB Is defined:C1231($1; "bottom")
$h:=OB Is defined:C1231($1; "height")
If ($b | $h)
If ($b)
$1.bottom:=$2+($1.bottom-$1.top)
$1.top:=$2
End if
If ($h)
$1.top:=$2
End if
Else
ASSERT:C1129(False:C215)
End if
Function ObjectSetPos
var $1 : Object
var $2; $3 : Integer
This:C1470.ObjectSetX($1; $2)
This:C1470.ObjectSetY($1; $3)
Function GetObjectMethodInfo
// $1 object
// $2 object name
// 0 none
// 1 std method : methode name match object name, object method file is the ObjectMethods folder
// 2 project method
// 3 custom
var $0 : Integer
var $1 : Object
var $2 : Text
var $in_object : Object
var $in_objectName : Text
var $encodedMethodFileName : Text
$in_object:=$1
$in_objectName:=$2
var $method; $ext; $objmethod : Text
var $l : Integer
$0:=0
If ($in_object#Null:C1517)
If (OB Is defined:C1231($in_object; "method"))
$encodedMethodFileName:=This:C1470.EncodeReservedFileCharacters($in_objectName)
$method:=$in_object.method
If ($method#"")
If (Length:C16($method)>5)
If ($method="@.4dm")
If ($method="ObjectMethods/@")
$objmethod:=Substring:C12($method; 0; Length:C16($method)-4)
$l:=Length:C16("ObjectMethods/")
$objmethod:=Substring:C12($method; $l+1; Length:C16($objmethod)-$l)
If (This:C1470.strcmp($objmethod; $encodedMethodFileName))
$0:=1
Else
$0:=3
End if
Else
$0:=3
End if
Else
$0:=2
End if
Else
$0:=2
End if
Else
$0:=2
End if
End if
End if
Function InsertInEntryOrderAfter
var $1; $2 : Text
var $0 : Boolean
var $in_ObjectName; $in_afterObjectName : Text
$in_ObjectName:=$1
$in_afterObjectName:=$2
$0:=False:C215
var $ind : Integer
var $entryOrder : Collection
If ($in_ObjectName#"")
$entryOrder:=This:C1470.editor.currentPage.entryOrder
If (This:C1470.editor.currentPage.entryOrder=Null:C1517)
$entryOrder:=New collection:C1472
This:C1470.editor.currentPage.entryOrder:=$entryOrder
End if
If ($entryOrder.indexOf($in_ObjectName)=-1)
If ($in_afterObjectName="")
$ind:=$entryOrder.length
Else
$ind:=$entryOrder.indexOf($in_afterObjectName)
End if
If ($ind>=0)
$entryOrder.insert($ind+1; $in_ObjectName)
$0:=True:C214
End if
End if
End if
Function InsertInEntryOrderBefore
var $1; $2 : Text
var $0 : Boolean
var $in_ObjectName; $in_beforeObjectName : Text
$in_ObjectName:=$1
$in_beforeObjectName:=$2
$0:=False:C215
var $ind : Integer
var $entryOrder : Collection