pyo3 python_calling_rust example

.bazelci/presubmit.yml

@@ -236,6 +236,7 @@ tasks:
       - "//..."
       - "-//ffi/rust_calling_c:matrix_dylib_test"
       - "-//ffi/rust_calling_c:matrix_dynamically_linked"
+      - "-//ffi/python_calling_rust/..."
       # The bindgen rules currently do not work on windows
       # see: https://github.com/bazelbuild/rules_rust/issues/919
       - "-//bindgen/..."

docs/BUILD.bazel

@@ -27,6 +27,7 @@ bzl_library(
         "@rules_rust//cargo:rules",
         "@rules_rust//crate_universe:rules",
         "@rules_rust//proto:rules",
+        "@rules_rust//python:rules",
         "@rules_rust//rust:rules",
         "@rules_rust//wasm_bindgen:rules",
     ],

examples/WORKSPACE.bazel

@@ -77,6 +77,10 @@ load("//sys:sys_deps.bzl", "sys_deps")
 
 sys_deps()
 
+load("@examples//ffi/python_calling_rust/raze:crates.bzl", "rules_rust_examples_ffi_python_calling_rust_fetch_remote_crates")
+
+rules_rust_examples_ffi_python_calling_rust_fetch_remote_crates()
+
 local_repository(
     name = "rules_rust_example_cargo_manifest_dir",
     path = "cargo_manifest_dir/external_crate",

examples/ffi/python_calling_rust/BUILD.bazel

@@ -0,0 +1,29 @@
+# Copyright 2020 The Bazel Authors. All rights reserved.
+#
+# Licensed under the Apache License, Version 2.0 (the "License");
+# you may not use this file except in compliance with the License.
+# You may obtain a copy of the License at
+#
+#    http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing, software
+# distributed under the License is distributed on an "AS IS" BASIS,
+# WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
+# See the License for the specific language governing permissions and
+# limitations under the License.
+
+load("@rules_python//python:defs.bzl", "py_test")
+load("@rules_rust//python:py_rust_library.bzl", "py_rust_library")
+
+py_rust_library(
+    name = "hello_py",
+    srcs = ["hello_py.rs"],
+    edition = "2018",
+    deps = ["//ffi/python_calling_rust/raze:pyo3"],
+)
+
+py_test(
+    name = "test",
+    srcs = ["test.py"],
+    deps = [":hello_py"],
+)

examples/ffi/python_calling_rust/hello_py.rs

@@ -0,0 +1,14 @@
+use pyo3::prelude::*;
+use pyo3::wrap_pyfunction;
+
+#[pyfunction]
+fn sum_as_string(a: usize, b: usize) -> PyResult<String> {
+    Ok((a + b).to_string())
+}
+
+#[pymodule]
+fn hello_py(_py: Python, m: &PyModule) -> PyResult<()> {
+    m.add_function(wrap_pyfunction!(sum_as_string, m)?)?;
+
+    Ok(())
+}

examples/ffi/python_calling_rust/test.py

@@ -0,0 +1,4 @@
+from ffi.python_calling_rust.hello_py import sum_as_string
+
+assert sum_as_string(1, 1) == "2"
+print("Ok!")

python/BUILD.bazel

@@ -0,0 +1,8 @@
+load("@bazel_skylib//:bzl_library.bzl", "bzl_library")
+
+package(default_visibility = ["//visibility:public"])
+
+bzl_library(
+    name = "rules",
+    srcs = glob(["**/*.bzl"]),
+)

python/py_rust_library.bzl

@@ -0,0 +1,51 @@
+"""
+"""
+
+load("@bazel_skylib//rules:copy_file.bzl", "copy_file")
+load("@rules_python//python:python.bzl", "py_library")
+load("@rules_rust//rust:rust.bzl", "rust_library")
+
+def py_rust_library(name, **kwargs):
+    """
+    Wraps a rust shared library that implements a python native extension to be usable by @rules_python targets.
+
+    Typically this is done through the use of a crate such as `pyo3` or `cpython`.
+
+    Args:
+        name (str): A unique name for this target.
+        **kwargs:   Passed directly to rust_library.
+    """
+
+    mangled = name + "_mangled_so"
+    rust_library(
+        name = mangled,
+        crate_type = "cdylib",
+        rustc_flags = select({
+            "@rules_rust//rust/platform:osx": [
+                "--codegen=link-arg=-undefined",
+                "--codegen=link-arg=dynamic_lookup",
+            ],
+            "//conditions:default": [],
+        }),
+        **kwargs
+    )
+
+    unix = name + "_unix"
+    copy_file(
+        name = unix,
+        src = mangled,
+        out = name + ".so",
+    )
+    windows = name + "_windows"
+    copy_file(
+        name = windows,
+        src = mangled,
+        out = name + ".pyd",
+    )
+    py_library(
+        name = name,
+        data = select({
+            "@rules_rust//rust/platform:windows": [windows],
+            "//conditions:default": [unix],
+        }),
+    )